Analiza nadomestega vezja transformatorja s programom ... - LES

MODELIRANJE ELEKTRIČNIH STROJEV 

Analiza nadomestnega vezja transformatorja 

s programskim paketom SPICE OPUS 

Danilo Makuc 

1 UVOD 

SPICE OPUS je brezplačen programski paket za analizo električnih vezij. Gre za izpeljanko simulatorja 

SPICE3, ki sicer ne ponuja programa za shematski vnos vezij, zato simulatorju vezje opišemo s tekstovno 

vhodno datoteko, ki jo lahko napišemo s katerimkoli urejevalnikom besedil. Omogoča vse standardne 

analize vezij (AC, DC, DC transfer curve, transfer function, transient analysis, ...) in ponuja tudi možnost 

izrisovanja grafov. 

V nadaljevanju je predstavljen izračun obratovalnega stanja enofaznega transformatorja s pomočjo analize 

nadomestnega vezja transformatorja s programskim paketom SPICE OPUS. Za razumevanje in spremljanje 

opisanih postopkov se predvideva, da ima bralec omenjeni programski paket instaliran in ima možnost 

urejanja enostavnih tekstovnih datotek. 

Čeprav se z doslednim prepisovanjem ukazov, ki so podani v tem gradivu, da izvesti celotno analizo 

nadomestnega vezja transformatorja, se za uspešno delo in razširjanje znanja s področja analize vezij 

priporoča tudi knjiga Árpáda Bűrmena Uvod v programski paket SPICE OPUS. Knjiga predstavlja odličen 

pripomoček za začetnika in vsebuje opise osnovnih oz. najpogostejših ukazov za definicijo vezij in analiz ter 

obdelavo rezultatov. 

Povezavi: 

– programski paket SPICE OPUS: http://www.spiceopus.si 

– knjiga Uvod v programski paket SPICE OPUS: http://fides.fe.uni-lj.si/~arpadb/aev/rnv-spice.pdf 

2 ELEMENTI NADOMESTNEGA VEZJA TRANSFORMATORJA 

Pri analizi bomo uporabili nadomestno vezje transformatorja kot je prikazano na sliki 1. 

I 1 

R 1 X 1 X 2 ' R 2 ' I 2 ' 

I 0 

U 1 

R 0 X 0 

U 2 ' 

Slika 1: Nadomestno vezje enofaznega transformatorja. 

1/9


Vrednosti elementov, ki jih v praksi določimo s preizkusi na realnem transformatorju ali z izračuni v 

postopku projektiranja transformatorja, bodo za naš primer vnaprej znani. Obravnavali bomo 

transformator z nazivnimi podatki: 

S n = 200 VA, U 1n = 230 V, U 2n = 24 V, f = 50 Hz, 

katerega elementi nadomestnega vezja znašajo: 

R 1 = 4,5 Ω, X 1 = 0,8 Ω, R 2 ' = 4 Ω, X 2 ' = 0,75 Ω, R 0 = 4,4 kΩ, X 0 = 1,6 kΩ. 

Pri analizi obratovalnega stanja transformatorja bomo na primarno stran priključili vir napajanja, na 

sekundarno stran pa breme (slika 2). 

~ 

I 1 

R 1 X 1 X 2 ' R 2 ' I 2 ' 

I 0 

U 1 

R 0 X 0 

U 2 ' 

R b ' 

Slika 2: Vezje za izračun obratovalnega stanja transformatorja. 

Napetost napajalnega vira naj bo nazivna napetost primarja transformatorja, upornost bremena pa 

izračunajmo iz nazivnih podatkov: 

R 

U 

U 

24 

2 2 

= 2n 2n 

b 

2,88 Ω 

I 

= 2n 

S 

= n 

200 

= . (1) 

Transformator ima prestavo različno od 1, zato je potrebno upornost bremena reducirati na primarno 

stran: 

p 

U 

U 

1n 

= = = , (2) 

2n 

230 9,583 

24 

R ′ = R ⋅ p = ⋅ = . (3) 

2 2 

b b 

2,88 9,583 264,5Ω 

3 IZDELAVA VHODNE DATOTEKE ZA ANALIZO 

V vhodni datoteki definiramo vezje, analize, ki naj se izvedejo, in izpišemo ali obdelamo rezultate analize. 

Ker bomo vezje opisali v tekstovni obliki, je najbolje da si vezje narišemo, saj si bomo tako lažje 

predstavljali povezave, označili pa si bomo tudi vozlišča in uporabljena imena posameznih elementov. Na 

sliki 3 je celotno vezje, z vsemi označenimi vozlišči in elementi. 

r1 l1 r2 l2 

1 2 3 4 5 

v1 

~ 

r0 

l0 

rb 

0 

Slika 3: Vezje za analizo v programu SPICE OPUS. 

Analiza nadomestnega vezja transformatorja s programskim paketom SPICE OPUS 2/9

3.1 Opis vezja 


V vezju je potrebno reaktance (X 1 , X 2 ' in X 0 ) predstavili z induktivnostmi (L 1 , L 2 in L 0 ), zato iz podanih 

reaktanc, z upoštevanjem nazivne frekvence, izračunamo ustrezne vrednosti elementov: 

L 

X 0,8 

2π⋅ 

f 2π⋅50 

= 1 

= = 

1 

L 

X 0,75 

2π⋅ 

f 2π⋅50 

= 2 

= = 

2 

L 

X 1600 

2π⋅ 

f 2π⋅50 

= 0 

= = 

0 

25,5mH , (4) 

23,9 mH, (5) 

5,09 H. (6) 

Vrednosti vseh elementov so znane, zato lahko zapišemo opis vezja. Sledili bomo načrtu vezja na sliki 3, 

tako da dobimo naslednji zapis: 

Nadomestno vezje enofaznega transformatorja 

* enofazni napajalni vir Un*sqrt(2) 

v1 (1 0) dc=0 acmag=325.27 

* nadomestno vezje 

r1 (1 2) 4.5 

l1 (2 3) 25.5m 

l2 (3 4) 23.9m 

r2 (4 5) 4 

l0 (3 0) 5.09 

r0 (3 0) 4.4k 

* breme 

rb (5 0) 264.5 

Prva vrstica vhodne datoteke je rezervirana za naslov, zato vanjo vpišemo poljuben tekst, ki opisuje vezje. 

Temu sledi opis vezja, pri katerem lahko uporabljamo tudi komentarje, ki se od ostalega ločijo tako, da je 

na začetku vrstice zvezdica (*). Definicija vsakega elementa vezja vsebuje podatek o vozliščih, na katera je 

priključen, ter o vrednosti elementa. Tako je na primer upor r1 vezan med vozlišči 1 in 2, njegova vrednost 

pa znaša 4,5 Ω. Podobno so definirani vsi elementi vezja. Pri podatkih o vrednostih elementov lahko 

uporabljamo predpone (f=10 -15 , p=10 -12 , n=10 -9 u=10 -6 , m=10 -3 , k=10 3 , Meg=10 6 , G=10 9 , T=10 12 ). 

3.2 Ukazi za analizo vezja 

Vezje bomo analizirali s tako imenovano malosignalno kompleksno analizo (ac), kar pomeni, da gre za 

analizo v frekvenčem prostoru, privzet pa je harmoničen (sinusen) časovni potek vseh količin. Napajalni vir 

v1 definiramo z amplitudo (acmag) in faznim premikom (acphase) napetostnega signala, vrednost 

enosmerne komponente (dc) pa smo vpisali le zato, da program ne javlja opozorila, da le-ta ni vpisan in bo 

privzeta vrednost 0. Privzeta vrednost za fazni premik (kot) vira je 0, zato tega podatka ni potrebno pisati. 

Vhodni datoteki, ki že vsebuje opis vezja, dodamo še ukazni blok, ki se začne z vrstico .control, konča pa 

z .endc, in v katerega vpišemo ukaze za analizo in obdelavo rezultatov. Ker nas v našem primeru zanimajo 

razmere v vezju le pri nazivni frekvenci 50 Hz, bomo pri definiciji analize za spodnjo in zgornjo frekvenčno 

mejo uporabili isto frekvenco: 

.control 

* AC analiza pri 50 Hz 

ac lin 1 50 50 

.endc 

Če vhodno datoteko zaključimo z vrstico: 

.end 

jo že lahko uporabimo za simulacijo. Vse ukaze, ki se tičejo rezultatov lahko izvajamo neposredno v ukazni 

vrstici programa SPICE OPUS. Pravzaprav bi tako lahko izvedli vse ukaze, ki se v vhodni datoteki nahajajo v 

ukaznem bloku (med .control in .endc), saj je v vhodni datoteki nujen le opis vezja. 


4 ANALIZA VEZJA 


Vhodno datoteko, ki smo jo napisali v urejevalniku teksta, shranimo kot enostavno tekstovno (ASCII) 

datoteko ter ji damo končnico .cir, ki je nekakšen standard pri vhodnih datotekah za analize SPICE. Najbolje 

je, da datoteko shranimo kar v direktorij, kjer je instaliran programski paket SPICE OPUS, saj nam v ukazno 

vrstico tako ne bo potrebno vpisovati poti do datoteke. 

V našem primeru izgleda celotna datoteka (trafo1.cir) takole: 

Nadomestno vezje enofaznega transformatorja 


v1 (1 0) dc=0 acmag=325.27 


r1 (1 2) 4.5 

l1 (2 3) 25.5m 

l2 (3 4) 23.9m 

r2 (4 5) 4 

l0 (3 0) 5.09 

r0 (3 0) 4.4k 

* breme 

rb (5 0) 264.5 

.control 


ac lin 1 50 50 

.endc 

.end 

Zaženimo program SPICE OPUS in v ukazno vrstico vnesimo ime naše datoteke. Pritisnimo ENTER in ko se 

prikaže nova ukazna vrstica je analiza končana. Sedaj lahko z ukazi dostopamo do rezultatov. Najprej 

poglejmo kolikšen je tok v primarno navitje, zapišimo: 

print i(v1) 

in kot odgovor dobimo: 

i(v1) = -1.24741e+000,2.663388e-001 

Vrednost, ki smo jo dobili je tok v amperih zapisan v kompleksnem prostoru. Prva številka je realna, druga 

pa imaginarna komponenta. Mogoče nas preseneti predznak, vendar je pri virih kot pozitiven tok 

definirana tisti, ki teče v pozitivno sponko vira. V našem primeru je pozitivna sponka priključena v vozlišče 

1, tako da negativna smer realne komponente pomeni tok iz vira. Podobno lahko pogledamo tok skozi 

induktivnost L1: 

-> print i(l1) 

i(v1) = 1.24741e+000,-2.663388e-001 

Dobili smo enak rezultat, le predznak je nasproten, saj je tudi pri elementu induktivnost (l) kot pozitivna 

določena smer toka, ko le-ta teče v pozitivno sponko (prva sponka pri L1 v definiciji vezja je pozitivna, 

druga pa negativna). Neposredno lahko poiščemo le toke, ki tečejo skozi vire ali induktivnosti, a nas v 

našem primeru to ne omejuje, saj je pri zaporedni vezavi upora in induktivnosti tok skoznju enak. 

4.1 Izgube v bakru 

Z rezultati analize bomo izgube v bakru transformatorja določili tako, da izračunamo moč na elementih R1 

in R2, ki predstavljata upornosti primarnega in sekundarnega navitja. Ker toka skozi elementa nista enaka, 

bomo ločeno določili izgube obeh navitij: 

P = I ⋅ R , (7) 

2 

Cu1 1 1 

P = I ′ ⋅ R ′ . (8) 

2 

Cu2 2 2 



Videli smo, da so toki podani kot kompleksne vrednosti, zato bomo z ukazom poiskali absolutno vrednost 

toka, pri čemer pa ne smemo pozabiti, da so dobljene vrednosti amplitudne in ne efektivne vrednosti 

tokov, s katerimi računamo izgube. Absolutni vrednosti tokov I 1 in I 2 dobimo z ukazom: 

-> print mag(i(l1)) mag(i(l2)) 

mag(i(l1)) = 1.275523e+000 

mag(i(l2)) = 1.182572e+000 

V ukazu smo uporabili funkcijo mag(x) ki vrne absolutno vrednost (magnitude) kompleksnega števila x. V 

ukazu lahko uporabljamo različne matematične funkcije in operatorje, tako da si lahko izpišemo tudi 

efektivni vrednosti tokov: 

-> print mag(i(l1))/sqrt(2) mag(i(l2))/sqrt(2) 

mag(i(l1))/sqrt(2) = 9.019310e-001 

mag(i(l2))/sqrt(2) = 8.362049e-001 

Z znanima vrednostima primarnega (I 1 ) in sekundarnega toka (I 2 ') lahko izračunamo izgube v bakru 

transformatorja: 

P = I ⋅ R = 0,9019 ⋅ 4,5 = 3,66 W , (9) 

2 2 

Cu1 1 1 

P = I ′ ⋅ R ′ = 0,8362 ⋅ 4 = 2,797 W , (10) 

2 2 

Cu2 2 2 

PCu = PCu1 + PCu2 

= 3,66 + 2,797 = 6,457 W . (11) 

4.2 Izgube v železu 

Izgube v železu transformatorja so v nadomestnem vezju predstavljene kot moč, ki se troši na uporu r0. 

Ker toka skozi upore ne moremo neposredno odčitati, bomo moč izračunali s pomočjo napetosti na tem 

uporu: 

P 

Fe 

2 

U0 

= . (12) 

R 

0 

Podobno, kot smo prej dobili efektivni vrednosti tokov, poiščemo še efektivno napetost na uporu r0: 

-> print mag(v(3))/sqrt(2) 

mag(v(3))/sqrt(2) = 2.246088e+002 

Ker je upor r0 vezan med vozlišči 3 in 0, lahko v izrazu za napetost napišemo le vozlišče 3 (v(3)), saj 

program avtomatično smatra vozlišče 0 kot vozlišče s potencialom 0 V. V kolikor nas zanima napetost med 

poljubnima vozliščema a in b, pa bi zapisali v(a,b). 

Izgube v železu tako znašajo: 

P 

Fe 

2 2 

U0 

224,61 

= = = 11,47 W . (13) 

R 4400 

0 

4.3 Napetost na bremenu (sekundarju) in izkoristek 

Napetost na bremenu (vozlišče 5) dobimo na enak način, kot smo poiskali napetost na uporu R0: 

-> print mag(v(5))/sqrt(2) 

mag(v(5))/sqrt(2) = 2.211762e+002 

Efektivna napetost na bremenu je torej U 2 ' = 221,2 V, pri čemer ne smemo pozabiti, da je to napetost, ki je 

s prestavo reducirana na primarno stran. Dejanska napetost na bremenu je: 

U 

U ′ 

p 

221,2 

9,583 

2 

2 

= = = 23,08 V . (14) 



Glede na to, da je na sekundarju le upor je celotna oddana moč transformatorja enaka moči na tem uporu. 

Ker poznamo sekundarni tok I 2 ' in napetost U 2 ' lahko izračunamo to moč: 

P2 = I ′ 

2 

⋅ U ′ 

2 

= 0,8362⋅ 221,2 = 184,97 W . (15) 

Izkoristek je razmerje med oddano (P 2 ) in prejeto močjo (P 1 ). Oddano moč smo izračunali kot moč na uporu 

Rb, prejeta delovna moč pa v celoti krije izgube transformatorja (P Cu + P Fe ) in oddano moč (P 2 ): 

P1 = P2 + PCu + PFe = 184,97 + 6,457 + 11,47 = 202,89 W , (16) 

tako da izkoristek transformatorja v obravnavanem obratovalnem stanju znaša: 

P P 

184,97 184,97 

P P + P + P 184,97 + 6,457 + 11,47 202,89 

2 2 

η = = = = = 

1 2 Cu Fe 

0,912 . (17) 

V tem primeru smo prejeto moč izračunali kot vsoto vseh delovnih moči v nadomestnem vezju, lahko pa bi 

to moč dobili neposredno iz napetosti in toka primarja. Slednje je bolj uporabno, saj lahko tako izračunamo 

moč povsod tam kjer poznamo napetost in tok. Ker sta obe količini podani kot kompleksno zapisana 

kazalca amplitud ju zapišimo kot U in I. Kompleksno moč sestavljata realna komponenta P, ki predstavlja 

delovno moč, in imaginarna komponenta Q, ki pa je jalova moč. Kompleksno moč izračunamo: 

∗ ∗ 

U I U⋅I 

S = ⋅ = = P + jQ 

, (18) 

2 2 2 

pri čemer je I * konjugirana vrednost toka. Polovica izhaja iz dejstva, da obe vrednosti predstavljata 

amplitudi napetosti in toka, moč pa predstavlja produkt efektivnih vrednosti toka in napetosti. 

Izračunajmo moč, ki priteka v primar transformatorja s pomočjo zgornje enačbe (18). Ker OPUS SPICE ne 

pozna funkcije, ki konjugira kompleksno število, bomo konjugirano vrednost toka definirali kot novo 

kompleksno vrednost (a, b), katere realna komponenta a je realna komponenta toka, imaginarna 

komponenta b pa negativna vrednost imaginarne komponente toka (Re(I), -Im(I)). Dobimo kompleksno 

moč: 

-> print v(1)*(re(i(l1)),-im(i(l1)))/2 

v(1)*(re(i(l1)),-im(i(l1)))/2 = 2.028719e+002,4.331602e+001 

Rezultat je pričakovan: delovna moč znaša P = 202,87 W, jalova pa Q = 4,33 VAr. Dobljena delovna moč se 

praktično ne razlikuje od tiste izračunane z enačbo (16), razlika je le posledica zaokroževanj numeričnih 

vrednosti med računanjem. 

5 ANALIZA NADOMESTNEGA VEZJA BREZ DODATNEGA RAČUNANJA 

Pri vseh dosedanjih izračunih smo upoštevali podane vrednosti elementov ne tistih, ki dejansko nastopajo v 

definiciji vezja. Vrednosti smo izračunali sami s kalkulatorjem. V nadaljevanju si bomo pogledali, kako lahko 

s programom za analizo vezij, kakršen je OPUS SPICE, opravimo celotno analizo brez dodatnih izračunov. 

Vse ukaze, ki smo jih za opravljene izračune pisali v ukazno vrstico lahko vključimo v ukazni blok vhodne 

datoteke. Pri tem lahko definiramo tudi spremenljivke in doložimo izgled izpisa. Če bi v vhodno datoteko 

vključili naslednji ukazni blok, bi po zaključeni analizi vezja dobili izpisane tudi iskane vrednosti tokov in 

tokov (datoteka trafo2.cir): 

.control 


ac lin 1 50 50 

echo ------------------------------------------ 

echo Analiza nadomestnega vezja transformatorja 

echo ------------------------------------------ 

let I1eff=mag(i(l1))/sqrt(2) 

echo I1eff = {I1eff} A 

let I2eff=mag(i(l2))/sqrt(2) 

echo I2eff = {I2eff} A 


let U0eff=mag(v(3))/sqrt(2) 

echo U0eff = {U0eff} V 


echo U2eff = {U2eff} V 

.endc 


Rezultate analize bi dobili izpisane v takšni obliki: 

------------------------------------------ 


------------------------------------------ 

I1eff = 0.901930957306215 A 

I2eff = 0.836204878751522 A 

U0eff = 224.608780547155 V 

U2eff = 221.176190429779 V 

Če želimo, da iz analize vezja dobimo kar končne rezultate za izgube, napetost sekundarja in izkoristek 

transformatorja, pa bo potrebno iz definicije vezja izluščiti tudi vrednosti elementov. Če bi na primer radi 

poznali in uporabili vrednost elementa R1, je potrebno priti do ustreznega parametra elementa upornosti, 

ki vsebuje to informacijo. Parametre in njihove vrednosti, ki so na voljo za posamezen element, si lahko 

pogledamo z ukazom show. Na primer: 

-> show r1 

Resistor: Simple linear resistor 

device r1 

model R 

resistance 4.5 

i 1.28 

p 5.57 

m 1 

Tu je šlo za element r1, kjer parameter resistance ali krajše r vsebuje informacijo o vrednosti upornosti. Za 

dostopanje do parametrov posameznega elementa uporabimo posebno sintakso: 

@element[parameter] 

pri čemer je element ime elementa vezja, parameter pa željeni parameter tega elementa. Omenjeni zapis 

uporabljamo kot spremenljivko, saj lahko vrednost parametra tudi spreminjamo in ne le preberemo. Tako 

bi ukaz: 

print @r1[r] 

izpisal vrednost upornosti, ki jo ima element r1, medtem ko bi z ukazom: 

let @r1[r]=10 

spremenili vrednost upornosti elementa r1 na 10 Ω. Z ukazom let lahko definiramo in priredimo vrednosti 

svojim spremenljivkam, kar bomo uporabili tudi v našem primeru. 

Zaradi preglednosti bomo za vse količine definirali svoje spremenljivke tako, da lahko do njih dostopamo 

tudi kasneje in jih enostavno uporabimo v enačbah in izpisu. Definirali bomo naslednje spremenljivke: 

i1eff - efektivna vrednost primarnega toka, 

i2eff - efektivna vrednost sekundarnega toka, 

u2eff - efektivna vrednost sekundarne napetosti, 

u0eff - efektivna vrednost napetosti na elementu r0, 

pcu - izgube v bakru, 

pfe - izgube v železu, 

p1 - prejeta delovna moč, 

p2 - oddana delovna moč, 

izk - izkoristek transformatorja (v %), 



Definicije vezja ne spreminjamo, v ukazni blok pa sedaj zapišemo (datoteka trafo3.cir): 

.control 


ac lin 1 50 50 

echo ------------------------------------------ 

echo Analiza nadomestnega vezja transformatorja 

echo ------------------------------------------ 

let i1eff=mag(i(v1))/sqrt(2) 

let i2eff=mag(i(l2))/sqrt(2) 


let u2eff=mag(v(5))/sqrt(2) 

let pcu=i1eff^2*@r1[r]+i2eff^2*@r2[r] 

let pfe=u0eff^2/@r0[r] 

let p2=i2eff^2*@rb[r] 

let p1=re(v(1)*(re(i(l1)),-im(i(l1)))/2) 

let izk=p2/p1*100 

* izpis rezultatov 

echo "Izgube v bakru: " {pcu} W 

echo "Izgube v zelezu: " {pfe} W 

echo "Sekundarna napetost:" {u2eff} V 

echo "Prejeta moc: " {p1} W 

echo "Oddana moc: " {p2} W 

echo "Izkoristek: " {izk} % 

echo ------------------------------------------ 

.endc 

V vrsticah za izpis (echo) so spremenljivke zapisane v zavitih oklepajih, kar pomeni, da se bo izpisala 

vrednost spremenljivke. Po zagonu analize dobimo takšne rezultate: 

------------------------------------------ 


------------------------------------------ 

Izgube v bakru: 6.45761192985426 W 

Izgube v zelezu: 11.4657055224727 W 

Sekundarna napetost: 221.176190429779 V 

Prejeta moc: 202.871926953384 W 

Oddana moc: 184.948609501055 W 

Izkoristek: 91.1652056933203 % 

------------------------------------------ 

Izračunana napetost sekundarja je pravzaprav vrednost U 2 ' in gre za reducirano vrednost, upoštevajoč 

prestavo 1. Ker v nadomestnem vezju ni podatka o prestavi, bi bilo za izračun dejanske sekundarne 

napetosti, prestavo dodati kot spremenjivko in jo uporabiti pri izračunih. 

5.1 Sprememba nadomestnega vezja transformatorja 

Isto vhodno datoteko lahko uporabimo tudi za analizo nadomestnega vezja z drugimi vrednostmi 

elementov. Spremenimo le vrednosti elementov vezja pri definiciji vezja, medtem ko ukazni blok pustimo 

nespremenjen, saj bo pri izračunu upoštevana dejanska vrednost elementov. Če na primer upornost 

elementa r1 spremenimo na 5 Ω, dobimo naslednje rezultate: 

------------------------------------------ 


------------------------------------------ 




Prejeta moc: 202.501298275179 W 

Oddana moc: 184.241338011366 W 

Izkoristek: 90.982793483625 % 

------------------------------------------ 


5.2 Sprememba obratovalnega stanja transformatorja 


Če želimo analizirati še druga obratovalna stanja transformatorja lahko sedaj enostavno spremenimo 

breme, ki je priključeno na sekundar (med vozlišči 5 in 0). Kot primer priključimo na sekundar kondenzator 

s tako kapacitivnostjo, da bo transformator nazivno obremenjen (slika 4). 

r1 l1 r2 l2 

1 2 3 4 5 

v1 

~ 

r0 

l0 

cb 

0 

Slika 4: Vezje za analizo drugačnega obratovalnega stanja. 

S pomočjo nazivne moči in napetosti izračunajmo ustrezno reaktanco kondenzatorja. Da nam vrednosti ne 

bo potrebno preračunavati na primarno stran, lahko pri izračunu enostavno uporabimo kar primarno 

napetost in tako dobimo: 

X 

U 

U 

230 

2 2 

= 1n 1n 

C 

264,5Ω 

I 

= 1n 

S 

= n 

200 

= . (19) 

Seveda smo dobili enako vrednost reaktance, kot je bila izračunana upornost v prvem primeru (enačba 3). 

Iz dobljene reaktance pri 50 Hz izračunajmo kapacitivnost kondenzatorja, ki ga bomo vključili v vezje: 

C 

b 

1 1 

= = 

≐ 12μF . (20) 

2π⋅ f ⋅ X 2π⋅50⋅264,5 

C 

V vhodni datoteki se spremeni le definicija vezja, ki sedaj izgleda takole: 


v1 (1 0) dc=0 acmag=325.27 


r1 (1 2) 4.5 

l1 (2 3) 25.5m 

l2 (3 4) 23.9m 

r2 (4 5) 4 

l0 (3 0) 5.09 

r0 (3 0) 4.4k 

* breme 

cb (5 0) 12u 

Po analizi dobimo: 

------------------------------------------ 


------------------------------------------ 




Prejeta moc: 18.6538210656884 W 

Oddana moc: -6.98108237884298e-013 W 

Izkoristek: -3.7424409477605e-012 % 

------------------------------------------ 

Pri tem obratovalnem stanju prejeta moč krije le izgube transformatorja, saj je breme kondenzator in sta 

zato oddana delovna moč in izkoristek enaka nič. Dobljeni negativni vrednosti sta le posledica napake 

zaradi numeričnega izračuna. Kot zanimivost opozorimo še na dejstvo, da je pri čisti kapacitivni 

obremenitvi, napetost na sekundarju višja od tiste v prostem teku, v našem primeru za približno 5,5 %.

Analiza nadomestega vezja transformatorja s programom ... - LES

You also want an ePaper? Increase the reach of your titles

Delete template?

Save as template?