TP SAS 6 : Régression logistique binomiale - Lsta

M2 IFMA et MPE
TP SAS : Régression logistique binomiale
Dans ce TP, on s’intéresse à une population de limules (Horseshoe crab). Des biologistes ont observé
que l’on trouve parfois plusieurs mâles (appelés satellites) à proximité du nid d’une femelle limule où
un mâle est déjà installé. Il s’agit de déterminer quelles variables peuvent expliquer la présence ou
non de satellites près d’un nid. Les données sont disponibles dans le fichier Limule.txt. On dispose des
variables suivantes :
– la variable couleur de la carapace, codée du plus clair au plus foncé de 2 à 5 ;
– la variable épine qui décrit l’état des deux épines mobiles :
1 : les deux épines sont en bon état,
2 : une épine abîmée,
3 : deux épines abîmées ;
– la variable largeur de la carapace ;
– la variable nombre de satellites relevés près du nid ;
– la variable poids de la carapace.
Créez un répertoire consacré à cette séance SAS et associez ce répertoire à une librairie SAS que
vous nommerez RegLog. Importez les données du fichier Limule.dat dans une table SAS RegLog.Limule.
Décalez le code pour la couleur de la carapace de 1 à 4. Divisez par 1000 le poids des carapaces :
data RegLog.Limule;
infile ’’;
input couleur epine largeur satellite poids;
couleur = couleur - 1;
poids = poids/1000;
run;
Liaisons de la variables Satellite avec des variables catégorielles
1. Effectuez un test d’indépendance du χ 2 entre la variable satellite et la variable couleur :
proc freq data = RegLog.Limule;
tables couleur *satellite / chisq;
run;
1

2. Proposez un test du χ 2 plus raisonnable pour tester l’hypothèse d’indépendance entre couleur
et satellite. Pour cela, définissez :
– une nouvelle variable dark qui prend la valeur 1 si la couleur de la carapace vaut 4 est 0 sinon,
– une nouvelle variable satellite01 qui prend la valeur 1 si un satellite est observé près du nid et
qui vaut 0 sinon.
Effectuez un test du χ 2 entre les deux nouvelles variables satellite01 et dark.
3. Effectuez un test du χ 2 entre les variables satellite01 et epine.
Liaisons de la variable Satellite01 avec des variables continues
Dans cette section, on étudie les liaisons éventuelles entre la présence de satellites et le poids ou
la largeur de la carapace de la limule.
4. Pour chacune de ces deux variables continues, comparez les distributions en présence ou non de
satellites. On pourra dresser des nuages de points, des boxplots et des histogrammes.
5. Utilisez une procédure ttest pour discuter l’existence d’une liaison entre la présence d’un satellite
et la valeur prise par l’une ou l’autre des deux variables poids et largeur.
6. Que dire de l’information apportée par les deux variables poids et largeur
Probabilités a posteriori
Dans cette section, on cherche à modéliser la présence d’un satellite (variable satellite01) à l’aide
de la variable continue poids. Le code correspondant à cette section est disponible ici.
7. Affichez le nuage de des couples (poids,satellite01) :
title ’Présence d’’un satellite expliqué par le poids de la limule’;
proc gplot data= RegLog.Limule;
symbol color=brown value=dot;
plot satellite01 * poids ;
label satellite01=’Présence d’’un satellite’
poids=’Poids de la limule (en kg)’;
run;
8. On préfère au graphique précédent une représentation des probabilités a posteriori
p ↦→ P(présence d’un satellite | poids = p).
Pour représenter ces probabilités a posteriori, nous allons définir une partition en classes de poids
et estimer les probabilités sur ces classes. Une partition de la variable poids s’obtient facilement
en utilisant un format défini par l’utilisateur. Le code suivant définit un nouveau format qui, une
fois appliqué à la variable poids crée une partition des observations en 6 catégories de poids :
proc format;
value fpoids
0-1.5=’inf 1.5’
1.5-2=’1.5-2’
2-2.5=’2-2.5’
2.5-3=’2.5-3’
3-3.5=’3-3.5’
3.5-100=’sup 3.5’;
run;
data RegLog.Limulebis;
set RegLog.Limule;
format poids fpoids. ;
run;
2

Vérifiez que le format a été correctement affecté à la variable poids dans la tableRegLog.Limulebis
à l’aide d’une proc print. Il est maintenant possible de calculer les moyennes dans chaque classe
à l’aide d’une proc means :
proc means data=RegLog.Limulebis mean;
class poids;
var satellite01 poids;
output out=RegLog.Limulemean mean=presencesat poidsmean;
run;
Affichez la table RegLog.Limulemean dans laquelle les moyennes ont été enregistrées. Quel est le
format de la variable poidsmean de cette table Affectez un format numérique à cette variable
et dressez le graphique des probabilités a posteriori.
9. Le logarithme des côtes :
Ω : p ↦→
P(présence d’un satellite | poids = p)
P(pas de satellite | poids = p)
est-il linéaire en la variable poids Proposez une première estimation rudimentaire des coefficients
du modèle de régression logistique de la variable Satellite01 par la variable poids.
Régression logistique de Satellite01 par le poids
10. Effectuez la régression logistique de la présence d’un satellite par le poids de la limule :
proc logistic data = RegLog.Limule plot(only) = (roc effect);
title ’Régression logistique par le poids’;
model satellite01(event = ’1’) = poids / expb ctable pprob= 0.5;
run;
Analysez le code et interprétez les sorties.
Régression logistique de Satellite01 par une variable catégorielle
11. Cas dichotomique : effectuez la régression logistique de la présence d’un satellite par le variable
dark :
proc logistic data = RegLog.Limule plots(only) = oddsratio ;
title ’Régression logistique avec dark’;
class dark;
model satellite01(event = ’1’) = dark / expb ctable pprob= 0.5;
oddsratio dark;
run;
12. Cas polytomique : effectuez la régression logistique de la présence d’un satellite par le variable
épine :
proc logistic data = RegLog.Limule plots(only) = oddsratio;
title ’Régression logistique avec epine’;
class epine (param=ref ref=’1’);
model satellite01(event = ’1’) = epine / expb ctable pprob= 0.5;
oddsratio epine;
run;
3

Régression logistique de Satellite01 par le poids et la couleur
13. Définir formellement le modèle de régression logistique qui explique la présence d’un satellite
par les variables poids et dark.
14. Utilisez le code ci-dessous pour ajuster ce modèle de régression logistique sur les données. Y-at-il
un ≪ effet carapace foncée ≫ Comparez graphiquement les probabilités a posteriori pour les
carapaces foncées et claires.
proc logistic data = RegLog.Limule plots(only) = (roc oddsratio effect);
title ’Régression logistique avec poids et dark’;
class dark;
model satellite01(event = ’1’ ) = poids dark / expb ctable pprob= 0.5;
oddsratio dark;
oddsratio poids;
run;
Régression logistique et sélection de variable
15. Discutez les sorties fournies par la code ci-dessous :
proc logistic data = RegLog.Limule plots(only) = (roc oddsratio effect);
title ’Régression logistique avec les quatre variables’;
class epine dark;
model satellite01 = poids largeur epine dark / ctable pprob= 0.5;
oddsratio dark;
oddsratio poids;
oddsratio largeur;
oddsratio epine;
effectplot slicefit(sliceby=epine plotby=dark);
run;
16. Effectuez une sélection de variable par un algorithme backward pour identifier un modèle de
régression logistique parcimonieux en utilisant l’option selection = stepwise dans l’instruction
model :
proc logistic data = RegLog.Limule plots(only) = (roc oddsratio effect);
title ’Régression logistique et sélection de variable’;
class epine dark;
model satellite01 = poids largeur epine dark / ctable pprob= 0.5
selection = backward ;
run;
4