Laborator 5. Colectii de date PL/SQL In multe limbaje de ...

Anca Ion, Proiectarea Bazelor de Date, 2010
Laborator 5. Colectii de date PL/SQL
In multe limbaje de programare folosim colectii de date cum ar fi: vectori, liste, tabele,
multimi si arbori. Aceste tipuri de date pot fi modelate in aplicatiile cu baze de date folosind
PL/SQL - TABLE si VARRAY, care permit declararea tabelelor, vectorilor de dimensiune
fixa sau variabila.
COLECTIILE PL/SQL
PL/SQL ofera umaratoarele tipuri de colectii:
Tabelele grupate(nested) in care se pastreaza un numar arbitrar de elemente.
Putem defini tipuri SQL echivalente care sa permita ca tabele grupate sa fie
pastrate in baza de date si sa fie manipulate folosind SQL.
Tabelele indexate; sunt similare cu tabelele de dispersie din alte limbaje de
programare
Vectorii de dimensiune fixa (varray) pastreaza un numar fix de elemente.
Putem defini tipuri SQL echivalente care sa permita ca vectorii sa fie pastrati in
baza de date si manipulati folosind SQL, dar cu mai putina flexibilitate decat
tabelele grupate.
Colectii care desi au o singura dimensiune, pot fi modelate in vectori
multidimensionali prin crearea de colectii ale caror elemente sunt de asemenea
colectii.
o Ce sunt tabelele grupate (nested tables)
Tabelele grupate in PL/SQL reprezinta multimi de valori. Sunt asemanatoare
cu un vector unidimensional fara a–i declara dimensiunea (numarul de
elemente). Putem crea vectori multidimensionali prin crearea de tabele grupate
ale caror elemente sunt tot tabele grupate.
Oracle stocheaza intr-o ordine oarecare inregistrarile dintr-o tabela grupata.
Cand se citeste o tabela grupata din baza de date intr-o variabila PL/SQL,
randurile sunt indexate cu indecsi consecutive incepand cu 1. Aceasta permite
accesul la inregistrari individuale.
Diferentele intre tabele grupate si vectori:
1. Tabelele grupate nu au un numar stabilit de elemente ; dimensiunea unei tabele
grupate poate creste dinamic; totusi se impune o limita maxima a numarului de
elemente (1 .. 2147483647)
2. Tabelele grupate pot sa nu aiba indesci consecutivi. Se pot sterge elemente
dintr-o tabela grupata folosind procedura DELETE. Functia NEXT permite
iterarea elementelor dintr-o tabela grupata.
Exemplu: TYPE tblNumber IS TABLE OF NUMBER;
o Vectori de dimensiune fixa (Varrays)

Anca Ion, Proiectarea Bazelor de Date, 2010
Exemplu: TYPE grades IS vararray(10) OF VARCHAR2(64);
o Vectori asociati (tabele indexate)
Vectorii asociati sunt multimi de perechi (cheie, valoare); cheia este unica si
este folosita pentru a localiza valoarea corespunzatoare in vector. Cheia poate
fi intreg sau sir de caractere.
Exemplu: declararea tipurilor de colectii
DECLARE TYPE population_type IS TABLE OF NUMBER INDEX BY VARCHAR2(64);
country_population population_type;
continent_population population_type;
howmany NUMBER;
which VARCHAR2(64);
BEGIN
country_population('Greenland') := 100000; -- adauga o noua intrare
country_population('Iceland') := 750000; -- adauga o noua intrare
--Cautam o valoare in tabel corespunzatoare indexului 'Greenland'.
howmany := country_population('Greenland');
continent_population('Australia') := 30000000;
continent_population('Antarctica') := 1000; -- adauga o noua intrare
continent_population('Antarctica') := 1001; -- inlocuieste vechea valoare
--metodele FIRST si LAST returneaza primul, respectiv ultimul index al colectiei
which := continent_population.FIRST;
--!Afisati which
which := continent_population.LAST;
--!Afisati which
howmany := continent_population(continent_population.LAST);
--!Afisati howmany
END;
Deoarece vectorii asociati sunt folositi pentru a memora date temporare, in loc
de a memora date persistente, ei nu pot fi utilizate in comenzi SQL cum ar fi
INSERT si SELECT INTO.
Acestia pot deveni date persistente pentru o sesiune a bazei de date prin
declararea tipului intr-un pachet si atribuirea de valori in corpul pachetului.
DEFINIREA COLECTIILOR SI DECLARAREA VARIABILELOR DE TIP
COLECTIE
Pentru a crea colectii, se poate defini un tip de date colectie in sectiunea de declaratii.
Exemplu: declararea unei variabile de tipul VARRAY
DECLARE
TYPE Calendar IS VARRAY(366) OF DATE;
Vectorii asociati (numiti si tabele indexate) permit inserarea de elemente cu chei
arbitare. Cheile pot sa nu fie consecutive.

Anca Ion, Proiectarea Bazelor de Date, 2010
Tipul de date pentru cheie poate fi: PLS_INTEGER, BINARY_INTEGER, sau
VARCHAR2, sau unul dintre subtipurile tipului VARCHAR2: VARCHAR, STRING,
sau LONG. PLS_INTEGER si BINARY_INTEGER sunt identice.
Exemplu: declararea unei variabile de tipul vector asociat(tabel indexat)
DECLARE
TYPE EmpTabTyp IS TABLE OF employees%ROWTYPE INDEX BY PLS_INTEGER;
emp_tab EmpTabTyp;
BEGIN
/* selectarea angajatului si salvarea lui in variabila emp_tab */
SELECT * INTO emp_tab(1) FROM employees WHERE employee_id = 100;
END;
Observatie: pentru a adauga mai multe intregistrari trebuie creat un cursor (vezi
laboratorul 3 (pg.4-5), exemplu cursor implicit)
o Declararea variabilelor de tip colectie in PL/SQL
Exemplu: declararea tabelelor grupate, a vectorilor cu dimensiune fixa, vectori
asociati
DECLARE
TYPE nested_type IS TABLE OF VARCHAR2(30);
TYPE varray_type IS VARRAY(5) OF INTEGER;
TYPE assoc_array_num_type IS TABLE OF NUMBER INDEX BY PLS_INTEGER;
TYPE assoc_array_str_type IS TABLE OF VARCHAR2(32) INDEX BY PLS_INTEGER;
TYPE assoc_array_str_type2 IS TABLE OF VARCHAR2(32) INDEX BY VARCHAR2(64);
v1 nested_type;
v2 varray_type;
v3 assoc_array_num_type;
v4 assoc_array_str_type;
v5 assoc_array_str_type2;
BEGIN
--initializare
v1 := nested_type('Shipping','Sales','Finance','Payroll');
v2 := varray_type(1, 2, 3, 4, 5); -- numai 5 intregi poti fi aduagati, deoarece dim maxima este 5
v3(99) := 10;
v3(7) := 100; -- subscripturile pot fi numai numere intregi
v4(42) := 'Smith'; -- subscripturile pot fi numai numere intregi
v4(54) := 'Jones';
v5('Canada') := 'North America'; -- subscripturile pot fi si siruri de caractere
v5('Greece') := 'Europe';
END;
Exemplu: declararea colectiilor folosind %TYPE
DECLARE
TYPE few_depts IS VARRAY(10) OF VARCHAR2(30);
TYPE many_depts IS VARRAY(100) OF VARCHAR2(64);
some_depts few_depts;
local_depts some_depts%TYPE;
global_depts some_depts%TYPE;
BEGIN
NULL;
END;

Anca Ion, Proiectarea Bazelor de Date, 2010
o Initializarea si referirea colectiilor
Exemplu: initializarea unei tabele grupate folosind un constructor(care apare ca o
functie cu acelasi nume ca si tipul colectiei):
DECLARE
TYPE dnames_tab IS TABLE OF VARCHAR2(30);
dept_names dnames_tab;
BEGIN
dept_names := dnames_tab('Shipping','Sales','Finance','Payroll');
END;
Deoarece o tabela grupata nu are o dimensiune fixa declarata, se pot pune cate
elemente se doresc in constructor.
Exemplu: initializarea unui vector de dimensiune fixa folosind un constructor
care apare ca o functie cu acelasi nume ca tipul colectiei:
DECLARE
--in vector se pune limita superioara pentru numarul de elemente
TYPE dnames_var IS VARRAY(20) OF VARCHAR2(30);
dept_names dnames_var;
BEGIN
dept_names := dnames_var('Shipping','Sales','Finance','Payroll');
END;
Daca in declaratia tipului nu este definita constrangerea NULL, se pot transmite si
elemente nule in constructor.
Exemplu:
DECLARE
TYPE dnames_tab IS TABLE OF VARCHAR2(30);
dept_names dnames_tab;
TYPE dnamesNoNulls_type IS TABLE OF VARCHAR2(30) NOT NULL;
BEGIN
dept_names := dnames_tab('Shipping', NULL,'Finance', NULL);
END;
Daca constructorul apelat este fara argumente atunci se va crea o colectie vida.
DECLARE
TYPE dnames_var IS VARRAY(20) OF VARCHAR2(30);
dept_names dnames_var;
BEGIN
IF dept_names IS NULL THEN
DBMS_OUTPUT.PUT_LINE('Inainte de initializare, vectorul este nul.');
-- deoarece vectorul este nul nu putem sa verificam atributul COUNT
-- DBMS_OUTPUT.PUT_LINE(Vectorul are ' || dept_names.COUNT || ' elemente.');

Anca Ion, Proiectarea Bazelor de Date, 2010
ELSE
DBMS_OUTPUT.PUT_LINE('Inainte de initializare, vectorul nu este nul.');
END IF;
dept_names := dnames_var(); -- initializarea vectorului
IF dept_names IS NULL THEN
DBMS_OUTPUT.PUT_LINE('Dupa initializare, vectorul este nul.');
ELSE
DBMS_OUTPUT.PUT_LINE('Inainte de initializare, vectorul nu este nul.');
DBMS_OUTPUT.PUT_LINE('Vectorul are ' || dept_names.COUNT || ' elemente.');
END IF;
END;
o Cum accesam elementele din colectii
Fiecare referire la un element dintr-o colectie implica numele colectiei si indexul
(subscriptul) inchis intre paranteze rotunde.
collection_name(index)
unde index este o expresie care este un intreg in cele mai multe cazuri dar poate fi
si un VARCHAR2 pentru vectorii asociati in care cheile sunt declarate ca siruri de
caractere.
Limitele pentru subscript sunt:
Pentru tabele grupate: 1 .. 2147483647
Pentru vectori cu dim fixa 1 .. size_limit, (size_limit nu depaseste
2147483647).
Pentru vectorii asociati cu chei numerice -2147483648 la 2147483647.
Pentru vectorii asociati cu chei de tip string lungimea cheii depinde de
declaratia tipului VARCHAR2.
Exemplu:
DECLARE
TYPE Roster IS TABLE OF VARCHAR2(15);
names Roster := Roster('D Caruso', 'J Hamil', 'D Piro', 'R Singh');
BEGIN
FOR i IN names.FIRST .. names.LAST
LOOP
IF names(i) = 'J Hamil' THEN
DBMS_OUTPUT.PUT_LINE(names(i));
END IF;
END LOOP;
verify_name(names(3));
END;
--creati procedura
PROCEDURE list_name(the_name VARCHAR2) IS
BEGIN
DBMS_OUTPUT.PUT_LINE(the_name);
END;
Exemplu:

Anca Ion, Proiectarea Bazelor de Date, 2010
DECLARE
TYPE sum_multiples IS TABLE OF PLS_INTEGER INDEX BY PLS_INTEGER;
n PLS_INTEGER := 5;
sn PLS_INTEGER := 10;
m PLS_INTEGER := 3;
BEGIN
DBMS_OUTPUT.PUT_LINE('Suma primelor ' || TO_CHAR(n) || ' inmultite cu ' ||
TO_CHAR(m) || ' este ' || TO_CHAR(get_sum_multiples (m, sn)));
END;
--creati functia
FUNCTION get_sum_multiples(multiple IN PLS_INTEGER, num IN PLS_INTEGER)
RETURN sum_multiples IS
s sum_multiples;
BEGIN
FOR i IN 1..num LOOP
s(i) := multiple * ((i * (i + 1)) / 2) ;
END LOOP;
RETURN s;
END get_sum_multiples;
o Atribuirea de elemente unei colectii
colectie1(index) := colectie2;
unde colectie2 este o alta colectie cu acelasi tip cu elementele ca si colectie1.
Se pot folosi si operatorii pentru atribuiri de colectii: SET, MULTISET UNION,
MULTISET INTERSECT si MULTISET EXCEPT.
Exemplu: compatibilitate de tip la atribuirea colectiilor
DECLARE
TYPE last_name_typ IS VARRAY(3) OF VARCHAR2(64);
TYPE surname_typ IS VARRAY(3) OF VARCHAR2(64);
-- aceste 2 var au acelasi tip de data.
group1 last_name_typ := last_name_typ('Jones','Wong','Marceau');
group2 last_name_typ := last_name_typ('Klein','Patsos','Singh');
-- a 3-a var are o declaratie asemanatoare dar n uare acelasi tip
group3 surname_typ := surname_typ('Trevisi','Macleod','Marquez');
BEGIN
group1 := group2;
--group3 := group2; -- se genereaza o eroare
END;
Exemplu: atribuirea tabelelor grupate folosind operatorii SET, MULTISET
UNION, MULTISET INTERSECT si MULTISET EXCEPT
DECLARE
TYPE nested_typ IS TABLE OF NUMBER;
nt1 nested_typ := nested_typ(1,2,3);
nt2 nested_typ := nested_typ(3,2,1);
nt3 nested_typ := nested_typ(2,3,1,3);

nt4 nested_typ := nested_typ(1,2,4);
answer nested_typ;
BEGIN
answer := nt1 MULTISET UNION nt4; -- (1,2,3,1,2,4)
print_nested_table(answer);
answer := nt1 MULTISET UNION nt3; -- (1,2,3,2,3,1,3)
print_nested_table(answer);
answer := nt1 MULTISET UNION DISTINCT nt3; -- (1,2,3)
print_nested_table(answer);
answer := nt2 MULTISET INTERSECT nt3; -- (3,2,1)
print_nested_table(answer);
answer := nt2 MULTISET INTERSECT DISTINCT nt3; -- (3,2,1)
print_nested_table(answer);
answer := SET(nt3); -- (2,3,1)
print_nested_table(answer);
answer := nt3 MULTISET EXCEPT nt2; -- (3)
print_nested_table(answer);
answer := nt3 MULTISET EXCEPT DISTINCT nt2; -- ()
print_nested_table(answer);
END;
--creati procedura
PROCEDURE print_nested_table(the_nt nested_typ) IS
output VARCHAR2(128);
BEGIN
IF the_nt IS NULL THEN
DBMS_OUTPUT.PUT_LINE('Results: ');
RETURN;
END IF;
IF the_nt.COUNT = 0 THEN
DBMS_OUTPUT.PUT_LINE('Results: empty set');
RETURN;
END IF;
FOR i IN the_nt.FIRST .. the_nt.LAST
LOOP
output := output || the_nt(i) || ' ';
END LOOP;
DBMS_OUTPUT.PUT_LINE('Results: ' || output);
END;
Anca Ion, Proiectarea Bazelor de Date, 2010