Turbo PMAC Users Manual Manual

12-12
Delta Tau Turbo PMAC User Manual
Which Direction to Home?: The most common of these situations is the case in which you do not know
on which side of the home trigger you are when you power-up. In this case, you must move into one of
the limit switches to make sure you are at one end of travel (this can be done by homing into the limit,
much as in the above example). Then you can do a homing move the other direction into the real home
trigger. A sample motion program routine that does this is:
CLOSE OPEN PROG 102 CLEAR
I223=10 ; Home speed 10 cts/msec positive direction
I224=$20000 ; Disable hardware limits
I225=$78208 ; Servo IC 2 Channel 2 for flags
I226=0 ; No home offset
I7222=2 ; Capture on rising edge of a flag
I7223=1 ; Use PLIM2 as flag (positive end limit)
HOME2 ; Home into limit
I223=-10 ; Home speed 10 cts/msec negative direction
I224=$0 ; Re-enable hardware limits
I7222=11 ; Capture on flag low and index channel high
I7223=0 ; Use HOME2 (home flag) as trigger flag
HOME2
CLOSE
; Do actual homing move
A sample PLC Program routine that does this is:
CLOSE
M233->X:$130,13,1 ; #2 Desired-velocity-zero bit
M245->Y:$140,10,1 ; #2 Home complete bit
OPEN PLC 11 CLEAR
I223=10 ; Home speed 10 cts/msec positive direction
I224=$20000 ; Disable hardware limits
I225=$78208 ; Servo IC 2 Channel 2 for flags
I226=0 ; No home offset
I7222=2 ; Capture on rising edge of a flag
I7223=1 ; Use PLIM2 as flag (positive end limit)
CMD"#2HM" ; Home into limit
WHILE (M245=1) ; Waits for Home Search to start
ENDWHILE
WHILE (M233=0) ; Waits for Home motion to complete
ENDWHILE
I223=-10 ; Home speed 10 cts/msec negative direction
I224=$0 ; Re-enable hardware limits
I7222=11 ; Capture on flag low and index channel high
I7223=0 ; Use HOME2 (home flag) as trigger flag
CMD"#2HM" ; Do actual homing move
WHILE (M245=1) ; Waits for Home Search to start
ENDWHILE
WHILE (M233=0) ; Waits for Home motion to complete
ENDWHILE
DIS PLC11 ; Disables PLC once Home is found
CLOSE ; End of PLC
Executing Individual Motor Moves