The PROVIDE Project Standard Computable General Equilibrium ...

PROVIDE Project Technical Paper 2003: 3 October 2003
6.2. GAMS Code
*############### 14. EQUATIONS ######################################
*## PRICE BLOCK
* For some c there are no imports hence only implement for cm(c)
PMDEF(c)$cm(c).. PM(c) =E= (PWM(c) *(1 + (TMADJ * tm(c)))) * ER ;
* For some c there are no exports hence only implement for ce(c)
PEDEF(c)$ce(c).. PE(c) =E= PWE(c) * ER * (1 - (TEADJ * te(c))) ;
PQDDEF(c)$(cd(c) OR cm(c))..
PQD(c) =E= PQS(c) * (1 + (TSADJ*ts(c))) ;
PQSDEF(c)$(cd(c) OR cm(c))..
PQS(c)*QQ(c) =E= (PD(c)*QD(c))+(PM(c)*QM(c)) ;
PXCDEF(c)$cx(c)..
PXC(c)*QXC(c) =E= (PD(c)*QD(c)) + (PE(c)*QE(c))$ce(c) ;
PXDEF(a).. PX(a) =E= SUM(c,actcomactsh(a,c)*PXC(c)) ;
PVADEF(a)..
PX(a)*(1-(TXADJ*tx(a)))*QX(a)
=E= (PVA(a)*QVA(a)) + (PINT(a)*QINT(a)) ;
PINTDEF(a).. PINT(a) =E= SUM(c,comactactco(c,a) * PQD(c)) ;
CPIDEF.. CPI =E= SUM(c,comtotsh(c)*PQD(c)) ;
PPIDEF.. PPI =E= SUM(c,vddtotsh(c)*PD(c)) ;
*## PRODUCTION BLOCK
* CES aggregation functions for Level 1 of production nest
QXPRODFN(a)$aqx(a)..
QX(a) =E= adx(a)*(deltax(a)*QVA(a)**(-rhocx(a))
+ (1-deltax(a))*QINT(a)**(-rhocx(a)))
**(-1/rhocx(a)) ;
QXFOC(a)$aqx(a)..
QVA(a) =E= QINT(a)*((PINT(a)/PVA(a))*(deltax(a)/
(1-deltax(a))))**(1/(1+rhocx(a))) ;
* Leontief aggregation functions for Level 1 of production nest
QINTDEF(a)$aqxn(a)..
QINT(a) =E= ioqintqx(a) * QX(a) ;
QVADEF(a)$aqxn(a)..
QVA(a) =E= ioqvaqx(a) * QX(a) ;
* CES aggregation functions for Level 2 of production nest
QVAPRODFN(a)..
QVA(a) =E= adva(a)*(SUM(f$deltava(f,a),
deltava(f,a)*FD(f,a)**(-rhocva(a))))
**(-1/rhocva(a)) ;
QVAFOC(f,a)$deltava(f,a)..
WF(f)*WFDIST(f,a) =E= PVA(a)*QVA(a)
*(SUM(fp$deltava(fp,a),deltava(fp,a)
*FD(fp,a)**(-rhocva(a))))**(-1)
*deltava(f,a)*FD(f,a)**(-rhocva(a)-1) ;
QINTDEQ(c).. QINTD(c) =E= SUM(a,comactactco(c,a)*QINT(a)) ;
COMOUT(c)$cx(c)..
QXC(c) =E= adxc(c)*(SUM(a$deltaxc(a,c),deltaxc(a,c)
*QXAC(a,c)**(-rhocxc(c))))**(-1/rhocxc(c)) ;
COMOUTFOC(a,c)$deltaxc(a,c)..
PXAC(a,c) =E= PXC(c)*QXC(c)
*(SUM(ap$deltaxc(ap,c),deltaxc(ap,c)
*QXAC(ap,c)**(-rhocxc(c))))**(-1)
*deltaxc(a,c)*QXAC(a,c)**(-rhocxc(c)-1) ;
© S. McDonald
55