The Programmer's Guide to TRSDOS Version 6 - Tim Mann's Home ...

LD A,L ;P/u hex or dec entry
BIT 6,B ;Error if switch entry
JP NZ,PRMERR
NSTUF LD (NULL1+1),A ;Stuff it in there
LD (NULL2+1),A
;*=*=*
; install new HIGH$ and move filter code
;*=*=*
LD HL,0 ;get current HIGH$
LD B,L
LD A,@HIGH$
RST 40
JR NZ,NOMEM
LD (OLDHI),HL ;put in filter header
;*=*=*
; Relocate internal references in driver
;*=*=*
LD IY,RELTAB ;Point to relocation tbl
LD DE,MODEND
XOR A ;Clear carry flag
SBC HL,DE
LD B,H ;Move to BC
LD C,L
RLOOP LD L,(IY) ;Get address to change
LD H,(IY+1)
LD A,H
OR L
JR Z,RXEND
LD E,(HL) ;P/U address
INC HL
LD D,(HL)
EX DE,HL ;Offset it
ADD HL,BC
EX DE,HL
LD (HL),D ;And put back
DEC HL
LD (HL),E
INC IY
INC IY
JR RLOOP ;Loop till done
;*=*=*
; Move driver
;*=*=*
RXEND LD DE,(OLDHI) ;Destination address
LD HL,MODEND ;Last byte of module
LD BC,LENGTH ;length of filter
LDDR
EX DE,HL ;Move new HIGH$ to HL
LD A,@HIGH$ ;Set new HIGH$ into the system
RST 40
INC HL ;Bump to filter entry
LD (IX+0),40H.OR.6 ;Stuff TYPE byte
LD (IX+1),L
LD (IX+2),H ;install addr into dcb
LD HL,0 ;Successful...
RET
;*=*=*
; Error message handling
;*=*=*
VIASET LD HL,VIASET$ ;'Must install...
DB 0DDH
NOMEM LD HL,NOMEM$ ;'No memory'
DB 0DDH
PRMERR LD HL,PRMERR$ ;'Parameter error'
LD A,@LOGOT
RST 40
LD HL,-1
RET
;*=*=*
; Data area
;*=*=*
HELLO$ DB 'DMP-500 BOLDFACE Filter Version 6.0a - '
DB 'Copyright 1983 by Roy Soltoff',LF,CR
PRMERR$ DB 'Parameter error!',CR
8-41