ACTIONSCRIPT 3 Developer’s Guide en

ACTIONSCRIPT 3.0 DEVELOPER’S GUIDE
Display programming
Adjusting DisplayObject colors
Flash Player 9 and later, Adobe AIR 1.0 and later
You can use the methods of the ColorTransform class (flash.geom.ColorTransform) to adjust the color of a display
object. Each display object has a transform property, which is an instance of the Transform class, and contains
information about various transformations that are applied to the display object (such as rotation, changes in scale or
position, and so forth). In addition to its information about geometric transformations, the Transform class also
includes a colorTransform property, which is an instance of the ColorTransform class, and provides access to make
color adjustments to the display object. To access the color transformation information of a display object, you can use
code such as this:
var colorInfo:ColorTransform = myDisplayObject.transform.colorTransform;
Once you’ve created a ColorTransform instance, you can read its property values to find out what color
transformations have already been applied, or you can set those values to make color changes to the display object. To
update the display object after any changes, you must reassign the ColorTransform instance back to the
transform.colorTransform property.
var colorInfo:ColorTransform = myDisplayObject.transform.colorTransform;
// Make some color transformations here.
// Commit the change.
myDisplayObject.transform.colorTransform = colorInfo;
Setting color values with code
Flash Player 9 and later, Adobe AIR 1.0 and later
The color property of the ColorTransform class can be used to assign a specific red, green, blue (RGB) color value to
the display object. The following example uses the color property to change the color of the display object named
square to blue, when the user clicks a button named blueBtn:
// square is a display object on the Stage.
// blueBtn, redBtn, greenBtn, and blackBtn are buttons on the Stage.
import flash.events.MouseEvent;
import flash.geom.ColorTransform;
// Get access to the ColorTransform instance associated with square.
var colorInfo:ColorTransform = square.transform.colorTransform;
// This function is called when blueBtn is clicked.
function makeBlue(event:MouseEvent):void
{
// Set the color of the ColorTransform object.
colorInfo.color = 0x003399;
// apply the change to the display object
square.transform.colorTransform = colorInfo;
}
blueBtn.addEventListener(MouseEvent.CLICK, makeBlue);
Last updated 6/6/2012
187