ACTIONSCRIPT 3 Developer’s Guide en

Chapter 31: Mouse input
Flash Player 9 and later, Adobe AIR 1.0 and later
Your application can create interactivity by capturing and responding to mouse input. Note that this section assumes
that you are already familiar with the ActionScript 3.0 event model. For more information, see “Handling events” on
page 125.
For information on discovering what kind of mouse support is available (such as persistent cursor, stylus or touch
input) during runtime, see “Discovering input types” on page 557.
More Help topics
flash.ui.Mouse
flash.events.MouseEvent
“Touch, multitouch and gesture input” on page 580
Capturing mouse input
Flash Player 9 and later, Adobe AIR 1.0 and later
Mouse clicks create mouse events that can be used to trigger interactive functionality. You can add an event listener to
the Stage to listen for mouse events that occur anywhere within the SWF file. You can also add event listeners to objects
on the Stage that inherit from InteractiveObject (for example, Sprite or MovieClip); these listeners are triggered when
the object is clicked.
As with keyboard events, mouse events bubble. In the following example, because square is a child of the Stage, the
event dispatches both from the sprite square as well as from the Stage object when the square is clicked:
var square:Sprite = new Sprite();
square.graphics.beginFill(0xFF0000);
square.graphics.drawRect(0,0,100,100);
square.graphics.endFill();
square.addEventListener(MouseEvent.CLICK, reportClick);
square.x =
square.y = 50;
addChild(square);
stage.addEventListener(MouseEvent.CLICK, reportClick);
function reportClick(event:MouseEvent):void
{
trace(event.currentTarget.toString() + " dispatches MouseEvent. Local coords [" +
event.localX + "," + event.localY + "] Stage coords [" + event.stageX + "," + event.stageY + "]");
}
Last updated 6/6/2012
574