ACTIONSCRIPT 3 Developer’s Guide en

ACTIONSCRIPT 3.0 DEVELOPER’S GUIDE
Display programming
function fadeBall(event:MouseEvent):void
{
myBall.alpha = .5;
}
myBall.addEventListener(MouseEvent.CLICK, fadeBall);
You can also alter the transparency of a display object using the color adjustments available through the
ColorTransform class. For more information, see “Adjusting DisplayObject colors” on page 187.
Masking display objects
Flash Player 9 and later, Adobe AIR 1.0 and later
You can use a display object as a mask to create a hole through which the contents of another display object are visible.
Defining a mask
To indicate that a display object will be the mask for another display object, set the mask object as the mask property
of the display object to be masked:
// Make the object maskSprite be a mask for the object mySprite.
mySprite.mask = maskSprite;
The masked display object is revealed under all opaque (nontransparent) areas of the display object acting as the mask.
For instance, the following code creates a Shape instance containing a red 100 by 100 pixel square and a Sprite instance
containing a blue circle with a radius of 25 pixels. When the circle is clicked, it is set as the mask for the square, so that
the only part of the square that shows is the part that is covered by the solid part of the circle. In other words, only a
red circle will be visible.
// This code assumes it's being run within a display object container
// such as a MovieClip or Sprite instance.
import flash.display.Shape;
// Draw a square and add it to the display list.
var square:Shape = new Shape();
square.graphics.lineStyle(1, 0x000000);
square.graphics.beginFill(0xff0000);
square.graphics.drawRect(0, 0, 100, 100);
square.graphics.endFill();
this.addChild(square);
// Draw a circle and add it to the display list.
var circle:Sprite = new Sprite();
circle.graphics.lineStyle(1, 0x000000);
circle.graphics.beginFill(0x0000ff);
circle.graphics.drawCircle(25, 25, 25);
circle.graphics.endFill();
this.addChild(circle);
function maskSquare(event:MouseEvent):void
{
square.mask = circle;
circle.removeEventListener(MouseEvent.CLICK, maskSquare);
}
circle.addEventListener(MouseEvent.CLICK, maskSquare);
Last updated 6/6/2012
190