ACTIONSCRIPT 3 Developer’s Guide en

ACTIONSCRIPT 3.0 DEVELOPER’S GUIDE
Filtering display objects
Blur filter
Flash Player 9 and later, Adobe AIR 1.0 and later
The BlurFilter class smears, or blurs, a display object and its contents. Blur effects are useful for giving the impression
that an object is out of focus or for simulating fast movement, as in a motion blur. By setting the quality property of
the blur filter too low, you can simulate a softly out-of-focus lens effect. Setting the quality property to high results
in a smooth blur effect similar to a Gaussian blur.
The following example creates a circle object using the drawCircle() method of the Graphics class and applies a blur
filter to it:
import flash.display.Sprite;
import flash.filters.BitmapFilterQuality;
import flash.filters.BlurFilter;
// Draw a circle.
var redDotCutout:Sprite = new Sprite();
redDotCutout.graphics.lineStyle();
redDotCutout.graphics.beginFill(0xFF0000);
redDotCutout.graphics.drawCircle(145, 90, 25);
redDotCutout.graphics.endFill();
// Add the circle to the display list.
addChild(redDotCutout);
// Apply the blur filter to the rectangle.
var blur:BlurFilter = new BlurFilter();
blur.blurX = 10;
blur.blurY = 10;
blur.quality = BitmapFilterQuality.MEDIUM;
redDotCutout.filters = [blur];
Drop shadow filter
Flash Player 9 and later, Adobe AIR 1.0 and later
Drop shadows give the impression that there is a separate light source situated above a target object. The position and
intensity of this light source can be modified to produce a variety of different drop shadow effects.
The DropShadowFilter class uses an algorithm that is similar to the blur filter’s algorithm. The main difference is that
the drop shadow filter has a few more properties that you can modify to simulate different light-source attributes (such
as alpha, color, offset and brightness).
The drop shadow filter also allows you to apply custom transformation options on the style of the drop shadow,
including inner or outer shadow and knockout (also known as cutout) mode.
The following code creates a square box sprite and applies a drop shadow filter to it:
Last updated 6/6/2012
277