OpenOffice.org Macros Explained - LibreOffice-NA.US

The arguments passed to the Array function become data in the returned Variant array. The DimArray
function, on the other hand, interprets the arguments as the dimensions of an array to create (see Listing 21).
The arguments can be expressions, so a variable can be used to set the dimension.
Listing 21. Redimension array.
Sub ExampleDimArray
Dim a(), i%
Dim s$
a = Array(10, 11, 12)
s = "" & LBound(a()) & " " & UBound(a()) Rem 0 2
a() = DimArray(3)
REM the same as Dim a(3)
a() = DimArray(2, 1)
REM the same as Dim a(2,1)
i = 4
a = DimArray(3, i)
Rem the same as Dim a(3,4)
s = s & CHR$(10) & LBound(a(),1) & " " & UBound(a(),1) Rem 0, 3
s = s & CHR$(10) & LBound(a(),2) & " " & UBound(a(),2) Rem 0, 4
a() = DimArray() REM an empty array
MsgBox s, 0, "Example Dim Array"
End Sub
The Array and DimArray functions both return an array of Variants. The ReDim statement changes the
dimension of an existing array. This can change both individual dimensions and the number of dimensions.
The arguments can be expressions because the ReDim statement is evaluated at run time.
Dim e() As Integer, i As Integer
i = 4
ReDim e(5) As Integer REM Dimension is 1, a size of 0 To 5 is valid.
ReDim e(3 To 10) As Integer REM Dimension is 1, a size of 3 To 10 is valid.
ReDim e(3, i) As Integer REM Dimension is 2, a size of (0 To 3, 0 To 4) is valid.
Some tips regarding arrays:
• LBound and UBound work with empty arrays.
• An empty array has one dimension. The lower bound is zero and the upper bound is -1.
• Use ReDim to cause an existing array to become empty.
The ReDim statement supports the keyword Preserve. This attempts to save the data when the dimensions of
an array are changed. Increasing the dimension of an array preserves all of the data, but decreasing the
dimension causes data to be lost by truncation. Data can be truncated at either end. If an element in the new
array existed in the old array, the value is unchanged. Unlike some variants of BASIC, OOo Basic allows all
dimensions of an array to be changed while still preserving data.
Dim a() As Integer
ReDim a(3, 3, 3) As Integer
a(1,1,1) = 1 : a(1, 1, 2) = 2 : a(2, 1, 1) = 3
ReDim preserve a(-1 To 4, 4, 4) As Integer
Print "(" & a(1,1,1) & ", " & a(1, 1, 2) & ", " & a(2, 1, 1) & ")"
ReDim specifies both the dimensions and an optional type. If the type is included, it must match the type
specified when the variable is declared or OOo generates a compile-time error.
Listing 22 is a utility function that accepts a simple array and returns a string with all of the elements in the
array. The ReDim example code, also in Listing 22, uses ArrayToString.
48