SIMSCRIPT II.5 Programming Language

SIMSCRIPT II.5 Programming Language
2.27.2 A Data Analysis Program: 2
To illustrate the way in which the logical elements of a program may be separated into routines, this
example repeats the computations of the previous problem, but instead of computing the averages
of the data values, computes the average of a function of the values. As the function to be used may
conceivably vary for different sets of data, or under different circumstances, the function evaluation
is logically partitioned from the main body of the program, and written as a function routine. It may
then be both separately tested and altered without having to modify the main routine. Note that the
function routine must now be declared within the program preamble.
Program 2-3.
_______________________________________________________________________________
preamble
define VALUE as a real function
end
main
define LIST as a 1-dimensional array
define I,J, SEQ.LEN and N as integer variables
define TOLERANCE.VALUE, SUM and AVERAGE as real variables
read N
reserve LIST(*) as N
read LIST
read TOLERANCE.VALUE
for SEQ.LEN = 1 to N-1,
for I = 1 to N-SEQ.LEN
do
let SUM = 0
for J = 0 to SEQ.LEN
add VALUE(LIST(I+J)) to SUM
let AVERAGE = SUM/(SEQ.LEN+1)
if AVERAGE is less than TOLERANCE.VALUE
print 1 line with I, I + SEQ.LEN and AVERAGE thus
ITEMS *** THROUGH *** HAVE AN AVERAGE OF **.***
always
loop
release LIST(*)
stop
end
routine VALUE given VARIABLE
if VARIABLE is less than -1000
return with -1
otherwise
if VARIABLE is greater than 1000
return with 1
otherwise
return with VARIABLE/1000
end
_______________________________________________________________________________
90