SIMSCRIPT II.5 Programming Language

SIMSCRIPT II.5 Basic Concepts
while TOTAL.WEIGHT < LIMIT
do
read PASSENGER.NO, FARE, and BAGGAGE.WEIGHT
add BAGGAGE.WEIGHT to TOTAL.WEIGHT
add FARE to TOTAL.REVENUE
loop
In this example, the value of the variable TOTAL.WEIGHT is incremented for each set of passenger
data read. As long as TOTAL.WEIGHT does not equal or exceed the value LIMIT, the statements in
the do loop are repeated. When the logical condition becomes untrue, that is, TOTAL.WEIGHT
equals or exceeds LIMIT, the repetition terminates and control transfers to the statement following
loop.
An until phrase is similar to a while phrase, but the terminating condition may be expressed as
the logical complement of that used in the while phrase. The phrase:
until TOTAL.WEIGHT >= LIMIT
could be substituted for the while phrase in the above example with an identical effect. In the example
in the previous section, the calculation of an approximate value for PI, the accuracy of the
computation was controlled by an input data value limiting the magnitude of the divisor in included
terms of the series. It might seem more straightforward to specify directly a lower bound on the
size of the terms to be included in the summation. The following example uses an until phrase to
control the do loop:
read LOW.BOUND
let VALUE = 0
let SIGN = +1
let TERM = 1
let DIVISOR = +1
until TERM less than LOW.BOUND
do
add (TERM * SIGN) to VALUE
let DIVISOR = DIVISOR + 2
let SIGN = -SIGN
let TERM = 1/DIVISOR
loop
print 1 line with VALUE*4 as
The Approximate Value of Pi is *.******
stop
Recalling that for control phrases may control the repetition of single statements as well as do
loops, note that while and until statements may be used in the same way. Because a single statement
may not, for the present, appear to offer much scope for altering the logical condition, the usefulness
of this construction may not be immediately appreciated. It is mentioned here for
completeness and will be expanded on in later chapters.
23