Using Caché Objects - InterSystems Documentation

Streams
15.2.2 Copying Data between Streams
All streams contain a CopyFrom method which allows one stream to fill itself from another
stream. This can be used, for example, to copy data from a file into a stream property:
// open a text file using a %Library.File stream
Set file = ##class(%File).%New("\data\textfile.txt")
Do file.Open("RU") ; same flags as OPEN command--use "U" for streams
// Open a Person object containing a Memo stream
// and copy the file into Memo
Set person = ##class(Person).%New()
Do person.Memo.CopyFrom(file)
// save the person object and close it, then close the file
Do person.%Save()
Do person.%Close()
Do file.%Close()
15.2.3 Inserting Stream Data
Streams have both a temporary and a permanent storage location. All inserts go into the
temporary storage area, which is only made permanent when you save the stream. If you start
inserting into a stream, then decide that you want to abandon the insert, the data stored in the
permanent location will not be altered.
If you create a stream, start inserting, then do some reading you can call MoveToEnd and
then continue appending to the temporary stream data. However after you save the stream,
the data is moved to the permanent storage location. If you then reload the stream and start
inserting, it will insert into the temporary storage area, rather than appending to the permanently
stored data.
If this is the behavior you want you will need to create a temporary stream, for example:
Set test = ##class(Test).%OpenId(5)
Set tmpstream = ##class(%GlobalCharacterStream).%New()
Do tmpstream.CopyFrom(test.text)
Do tmpstream.MoveToEnd()
Do tmpstream.Write("append text")
Set test.text = tmpstream
Do tmpstream.%Close()
// Now do whatever you want with the test object
In this example, we create a temporary stream of the required type, then copy from the stream
stored in the Test object, which will put this data in the temporary storage area of our new
stream. Then we append to this stream and put its oref into the Test object and close it to keep
the reference counts correct.
136 Using Caché Objects