MIPS Assembly Language Programming

2.8. LOADS: THE PALINDROME.ASM PROGRAM 35
## $a0 - syscall parameters.
## $a1 - syscall parameters.
The first step of the algorithm is to read in the string from the user. This can be
done with the read_string syscall (syscall number 8), which is similar in function
to the fgets function in the C standard I/O library. To use this syscall, we need to
load into register $a0 the pointer to the start of the memory that we have set aside
to hold the string. We also need to load into register $a1 the maximum number of
bytes to read.
To set aside the space that we’ll need to need to store the string, the .space
directive can be used. This gives the following code:
.text
main: # SPIM starts by jumping to main.
## read the string S:
la $a0, string_space
li $a1, 1024
li $v0, 8 # load "read_string" code into $v0.
syscall
.data
string_space: .space 1024 # set aside 1024 bytes for the string.
Once we’ve got the string, then we can use algorithm 2.2 (on page 34). The first
step is simple enough; all we need to do is load the address of string_space into
register $t1, the register that we’ve set aside to represent A:
la $t1, string_space # A = S.
The second step is more complicated. In order to compare the character pointed
to by B with 0, we need to load this character into a register. This can be done with
the lb (load byte) instruction:
la $t2, string_space ## we need to move B to the end
length_loop: # of the string:
lb $t3, ($t2) # load the byte at B into $t3.
beqz $t3, end_length_loop # if $t3 == 0, branch out of loop.
addu $t2, $t2, 1 # otherwise, increment B,
b length_loop # and repeat
end_length_loop:
subu $t2, $t2, 2 ## subtract 2 to move B back past
# the ’\0’ and ’\n’.