Fitting Curves and Surfaces Using SAS Software - ISS - University of ...

Fitting Curves and Surfaces Using SAS Software
Version 1.1 (February 2007)
Example 4: Surface Fitting using Thin-Plate Smoothing Splines
The following example is taken from the SAS Sample Library and illustrates the use of TPSPLINE to fit a
smooth surface to the sulphate data listed in Annex 1. The data represent the deposition of sulphate (SO4) at
179 sites in 48 contiguous states of the United States in 1990. Each observation records the latitude and
longitude of the site as well as the SO4 deposition at the site measured in gram per square meter (g/m 2 ).
(i) Open the file tpsplin1.sas.
(ii) Submit the program by pressing F8.
The DATA step (shown below) creates a data set pred containing values of latitude and longitude over
a finely divided lattice. This data set will be offered to TPSPLINE as a scoring data set upon which the
estimated surface will be based.
data pred;
do latitude = 25 to 47 by 1;
do longitude = 68 to 124 by 1;
output;
end;
end;
run;
The TPSPLINE step specifies a range of values for the smoothing parameter.
proc tpspline data=sasgraph.so4;
ods output GCVFunction=gcv;
model so4 = (latitude longitude) /lognlambda=(-6 to 1 by 0.1);
score data=pred out=prediction1;
run;
The ods statement saves values of the generalised cross validation function, gcv, for the different
values of λ (or more precisely lognlambda (=log10(n*λ))) in an output data set called gcv. A plot of
gcv against lognlambda is presented below.
goptions reset=all;
axis1 minor=none;
axis2 minor=none;
title 'GCV Function';
proc gplot data=gcv;
plot gcv*lognlambda/ cframe=white
vaxis=axis1 haxis=axis2 ;
format gcv lognlambda d5.2;
symbol1 c=blue i=join v=none w=2;
run;
The gcv plot reveals a local minimum at around –2.56 and a global minimum around 0.277. The fitted
estimates saved in the data set prediction1 are based upon the global minimum.
It is instructive to compare the results with estimates based upon the local minimum.
Information Systems Services Page 14 of 22
Version 1.1 (Feb 2007) tut125.doc