Manual do FlexPDE v.5 - DEMAR

Manual do FlexPDE versão 5
Elementos do roteiro FlexPDE
• TITLE – título descritivo do problema.
• SELECT – parâmetros de controle do FlexPDE.
• VARIABLES – lista de variáveis.
• DEFINITIONS – definição de parâmetros, relações constitutivas ou matemáticas e funções.
• EQUATIONS – cada variável descrita em VARIABLES é associada à EDP correspondente.
• BOUNDARIES – descreve a geometria e as condições de contorno.
• MONITORS – desenha gráficos durante a execução do roteiro
• PLOTS – desenha os gráficos com os resultados do cálculo.
• END – término do roteiro.
Roteiro “template” padrão do FlexPDE
TITLE 'New Problem' { the problem identification }
COORDINATES cartesian2 { coordinate system, 1D,2D,3D, etc }
VARIABLES { system variables }
u { choose your own names }
! SELECT { method controls }
! DEFINITIONS { parameter definitions }
! INITIAL VALUES
EQUATIONS { PDE's, one for each variable }
div(grad(u))=0 { one possibility }
! CONSTRAINTS { Integral constraints }
BOUNDARIES { The domain definition }
REGION 1 { For each material region }
START(0,0) { Walk the domain boundary }
LINE TO (1,0) TO (1,1) TO (0,1) TO CLOSE
! TIME 0 TO 1 { if time dependent }
MONITORS { show progress }
PLOTS { save result displays }
CONTOUR(u)
END
Como descrever um problema físico no FlexPDE
O FlexPDE interpreta uma sequência de comandos textuais que descrevem as características
de um problema a ser resolvido no editor (CTRL E). A melhor forma de iniciar um novo problema é
modificando um existente. Em qualquer problema, as seguintes etapas devem ser descritas:
• Definir as variáveis (VARIABLES) e respectivas equações (EQUATIONS)
• Definir o domínio (BOUNDARIES)
• Definir os parâmetros dos materiais (DEFINITIONS)
• Definir as condições de contorno (BOUNDARIES)
• Definir os parâmetros temporais, se for problema em regime transiente (TIME 0 TO n)
• Especificar as saídas gráficas (MONITORS e PLOTS).
Novembro 2009 1

Como salvar um roteiro no FlexPDE
Para gravar um roteiro clicar na opção Domain Review (CTRL D) no menu Controls ou
executar o roteiro usando o comando CTRL R ou clicar na opção Run Script no menu Controls.
Notação matemática e simbólica
• Diferenciação: a derivada du/dx é denotada por dx(u). A derivada de segunda ordem
d 2 u/dx 2 é descrita como dxx(u). Os operadores diferenciais divergente ( ∇ •), gradiente
(∇ )e rotacional ( ∇ × ) são descritos pelos seus nomes na língua inglesa, respectivamente,
Div, Grad e Curl.
• Nomes: não são sensíveis à capitalização. F é o mesmo que f.
• Comentários: podem ser colocados no texto entre chaves { } ou com o símbolo ! que
ignora o comentário até o final da linha.
Variáveis e Equações
Duas coisas básicas que o FlexPDE precisa saber:
• Quais são as variáveis a serem analisadas
• Quais são as equações diferenciais que definem as variáveis
As seções VARIABLES e EQUATIONS do roteiro fornecem estas informações. As duas
são intimamente relacionadas pois deve haver uma equação para cada variável.
Exemplos
VARIABLES
Phi
EQUATIONS
Div(grad(Phi)) = 0
Quando houver duas ou mais variáveis, a associação com cada equação correspondente é
feita da forma mostrado no exemplo seguinte.
VARIABLES
A, B
EQUATIONS
A: Div(grad(A)) = 0
B: Div(grad(B)) = 0
Descrição do domínio do problema
Descrição de problemas 2D
Um problema de domínio 2D é descrito na seção BOUNDARIES que é constituído por
regiões (REGIONS), cada uma com as suas propriedades de materiais. Uma REGION pode conter
diversos subdomínios conexos (fechados), mas todos devem ter as mesmas propriedades dos
materiais.
Novembro 2009 2

• Uma especificação REGION inicia-se com a declaração REGION (ou
REGION "nome") e todos os laços seguintes ao cabeçalho são incluídos na região
• Outras REGION que ocorrem posteriormente no roteiro podem cobrir partes descritas por
REGIONs anteriores.
• A primeira REGION deve conter todo o domínio. Esta é uma convenção arbitrária e faz
com que a atribuição das condições de contorno seja mais fácil.
A forma de cada região é descrita percorrendo o perímetro e saltando de uma junção a outra
com segmentos LINE, SPLINE ou ARC. Cada segmento inicia-se com a declaração START e
retorna ao início com a palavra CLOSE (ou TO CLOSE).
Exemplo: região retangular constituída por quatro segmentos de reta:
START (x1,y1)
LINE TO (x2,y1) { Segmento 1 }
TO (x2,y2) { Segmento 2 }
TO (x1,y2) { Segmento 3 }
TO CLOSE { Segmento 4 }
Um polígono pode ser construído adicionando-se mais pontos e, consequentemente, mais
segmentos.
Exemplo: arcos podem ser construídos de diversas formas, a mais simples é especificando o
centro e o ângulo do arco:
START(r,0)
ARC(CENTER = 0,0) ANGLE = 360
Exemplo: arco especificando o centro e o ponto final:
START(r,0)
ARC(CENTER = 0,0) TO (0,r) { arco de 90 graus }
Um arco elíptico pode ser construído se a distância do centro a uma extremidade for
diferente da distância do centro ao ponto inicial. Os eixos da elipse estarão alinhados às direções
horizontal e vertical; não é possível construir uma elipse inclinada.
Laços também podem ser nomeados para referência posteriormente, como em:
START "Nome" (…)
O protótipo da seção BOUNDARIES é na forma:
BOUNDARIES
REGION 1
< laço fechado no entorno do domínio>
REGION 2
…
Pode-se construir o domínio um pedaço de cada vez, usando a opção Domain Review para
pré-visualizar o domínio.
Novembro 2009 3

Exemplo
BOUNDARIES
REGION 1 'caixa' { domínio retangular }
START (-1,-1)
LINE TO (1,-1)
TO (1,1)
TO (-1,1)
TO CLOSE
REGION 2 'bolha' { círculo no interior do domínio }
START 'anel' (1/2,0)
ARC(CENTER = 0,0) ANGLE = 360 TO CLOSE
END
Executando o exemplo listado acima através da opção Domain Review obtém-se as
seguintes figuras:
Geração da malha de elementos finitos
O FlexPDE gera automaticamente a malha de elementos finitos que se ajusta ao domínio,
utilizando triangulos quasi-equilaterais, cujos tamanhos são determinados pelo espaçamento entre
pontos explícitos na fronteira do domínio,pela curvatura dos subdomínios ou pela densidade
controlada pelo usuário.
No exemplo anterior a malha foi gerada automaticamente. Como exemplo de malha com
densidade controlada pelo usuário, pode-se fazer com que a malha do círculo seja mais densa
usando o comando modificador MESH_SPACING:
REGION 2 'bolha' { círculo interior }
START(1/2,0)
MESH_SPACING = 0.05
A malha resultante terá a seguinte forma:
Novembro 2009 4

Na maioria dos casos não é necessário intervir na geração de malha porque o FlexPDE
refinará adaptativamente a malha quando detectar uma forte curvatura na solução.
Definição de parâmetros do material
O FlexPDE descreve as propriedades dos materiais através de nomes de parâmetros
definidos na seção DEFINITIONS. A atribuição das propriedades dos materiais é feita no domínio
REGIONS, onde o valor pode ser alterado. O FlexPDE pode atribuir propriedades por parâmetros
constantes ou por meio de equações que relacionam a propriedade do material com a temperatura
ou outra grandeza física.
Por exemplo, considere a equação de calor, descrevendo um isolante circular de
condutividade 0.001 e um condutor circundante de condutividade 1. Primeiro, define-se o nome da
constante e atribui-lhe o valor padrão:
DEFINITIONS
k = 1
Este valor padrão de k será usado em cada REGION do problema, a menos que seja
redefinido em cada região. Introduzindo a constante k na equação:
EQUATIONS
Div(-k*grad(phi)) = 0
Especificando um valor regional na região 2:
...
REGION 2 'bolha'
k = 0.001
START(1/2,0)
ARC(CENTER = 0,0) ANGLE = 360
Novembro 2009 5

Pode-se definir o parâmetro k = 1 para o condutor na REGION 1, se quiser explicitar para
efeito de clareza.
Condições de contorno
As condições de contorno são especificadas como modificadores durante o percurso de
definição do domínio (BOUNDARIES). O FlexPDE possui dois tipos de condição de contorno:
• Dirichlet ou condição de valor (VALUE)
• Neumann ou condição natural (NATURAL)
A condição de contorno VALUE pode ser uma expressão aritmética incluindo dependências
não lineares e dependência de variáveis.
A condição de contorno NATURAL especifica o fluxo na fronteira do domínio. A definição
pode ser uma expressão aritmética incluindo dependências não lineares e dependência de variáveis.
Com a equação de Laplace a condição de contorno NATURAL é equivalente à condição de
Neumann ou condição derivativa normal.
Cada declaração estabelecendo as condições de contorno tem como argumento o nome de
uma variável. Este nome associa a condição de contorno com uma variável da lista de equações,que
na realidade é a equação que é modificada pela condição de contorno.
No exemplo seguinte será atribuída temperatura zero na fronteira de baixo, uma superfície
isolada no lado direito, temperatura de 1 na fronteira de cima e uma fronteira isolada do lado
esquerdo:
…
REGION 1 'caixa'
START(-1,-1)
{ Phi = 0 na linha de baixo: }
VALUE(Phi) = 0 LINE TO (1,-1)
{ derivada normal = 0 no lado direito: }
NATURAL(Phi)=0 LINE TO (1,1)
{ Phi = 1 no topo: }
VALUE(Phi)=1 LINE TO (-1,1)
{ derivada normal = 0 no lado esquerdo: }
NATURAL(Phi)=0 LINE TO CLOSE
Observar que as condições VALUE ou NATURAL declaram uma condição que será
aplicada aos segmentos da fronteira subsequentes até que a declaração seja alterada.
Observar que a forma segmento (LINE ou ARC) deve ser reiniciada após uma troca de
condição de contorno.
Tipos de gráficos de exploração de resultados
Os comandos MONITORS e PLOTS requisitam os gráficos dos resultados do cálculo.
MONITORS: usado para obter informações durante o progresso da solução.
PLOTS: especifica os gráficos finais que serão desenhados.
Tipos de gráficos no FlexPDE
Novembro 2009 6

• CONTOUR: curves de nível; podem ser preenchidas com cor.
• SURFACE: curva de superfície 3D.
• VECTOR: curva de campo de vetores
• ELEVATION: curva X-Y em corte num caminho definido em BOUNDARIES
• SUMMARY: relatório textual
Exemplo:
Curva de nível (CONTOUR) de temperatura, curva de campo vetorial (VECTOR) do fluxo de
calor, k*grad(Phi), curva X-Y (ELEVATION) da distribuição de temperatura numa linha no centro
da geometria e uma curva X-Y do fluxo de calor normal à superfície da bolha.
PLOTS
CONTOUR(Phi)
VECTOR(-k*grad(Phi))
ELEVATION(Phi) FROM (0,-1) to (0,1)
ELEVATION(Normal(-k*grad(Phi))) ON 'anel'
O registro das curvas obtidas em PLOTS é gravado com a extensão .PG5 e com o nome do
arquivo roteiro .PDE. Esses gráficos gravados podem ser visualizados através da opção VIEW no
menu principal do FlexPDE.
Os gráficos produzidos pelo MONITORS não são gravados, de modo que é recomendado
que sejam usados com a finalidade de depuração do roteiro FlexPDE.
Além dos gráficos apresentados, o FlexPDE aceita outras formas de gráficos como GRID e
HISTORIES.
Roteiro completo
TITLE 'Fluxo de calor em torno de uma bolha isolada'
VARIABLES
phi { Temperatura }
DEFINITIONS
k = 1 { condutividade }
r = 0.5 { raio da bolha }
EQUATIONS
Div(-k*grad(phi)) = 0
BOUNDARIES
REGION 1 'caixa'
START(-1,-1)
VALUE(Phi)=0 LINE TO (1,-1)
NATURAL(Phi)=0 LINE TO (1,1)
VALUE(Phi)=1 LINE TO (-1,1)
NATURAL(Phi)=0 LINE TO CLOSE
REGION 2 'bolha'
k = 0.001 { redefinição da condutividade na bolha }
START 'anel' (r,0)
ARC(CENTER = 0,0) ANGLE = 360 TO CLOSE
PLOTS
CONTOUR(phi)
VECTOR(-k*grad(phi))
ELEVATION(phi) FROM (0,-1) to (0,1)
ELEVATION(Normal(-k*grad(phi))) ON 'anel'
Novembro 2009 7

END
Os gráficos de resultado do roteiro completo para o cálculo do fluxo de calor em torno de
uma bolha isolada são os seguintes:
Novembro 2009 8