Adobe Director Basics

ADOBE DIRECTOR BASICS
3D: Controlling appearance
Using a Bitmap member also gives you a simple way to define the origin point for the mesh resource: you can use the
member.regPoint of the Bitmap member. A Bitmap member has a width and a height, measured in pixels. A bitmap
of n x m pixels generates a rectangular terrain of (n - 1) columns and (m - 1) rows. Each pixel can store one of 256
different values, from 0 to 255. To convert these numbers into world unit dimensions, you need to apply a different
scale to each axis.
Here is a handler that you can use to find what scale to use for each axis. It returns a list containing three floating-point
values, in the format [, , ].
-- Lingo syntax
on GetScale(aBitmap, xUnits, yUnits, zUnits)
vColumns = float(aBitmap.width - 1)
vRows = float(aBitmap.height - 1)
vScale = []
vScale.append(xUnits / vColumns)
vScale.append(yUnits / 255.0)
vScale.append(zUnits / vRows)
return vScale
end GetScale
Example usage:
vScaleList = GetScale(member "HeightMap", 100, 39, 64)
put vScaleList
-- [6.6667, 0.1529, 3.3684]
You can now use the Bitmap's grayscale image data, its regPoint, and the scale list that you have just created to generate
a series of vertex points.
on GetVertexListFromBitmap(aBitmap, aScale)
vVertexList = []
vScaleX = aScale[1]
vScaleY = aScale[2]
vScaleZ = aScale[3]
vImage = aBitmap.image
vColumns = vImage.width - 1
vRows = vImage.height - 1
vRegPoint = aBitmap.regPoint
vOffsetX = vRegPoint.locH * vColumns / float(vColumns + 1)
vOffsetZ = vRegPoint.locV * vRows / float(vRows + 1)
repeat with zz = 0 to vRows
repeat with xx = 0 to vColumns
vX = (xx - vOffsetX) * vScaleX
vPixel = vImage.getPixel(xx, zz).red
vY = vPixel * vScaleY
vZ = (zz - vOffsetZ) * vScaleZ
vVector = vector(vX, vY, vZ)
vVertexList.append(vVector)
end repeat
end repeat
return vVertexList
end GetVertexListFromBitmap
Below is the output generated by a Bitmap member named “3x3” that displays 8 black pixels in a square around a
central white pixel. The member's regPoint is at point(3, 0), on the top right edge of the black square. The scale has
been chosen to create a mesh resource that will be 20 units wide along the xAxis and 30 units along the zAxis. The
maximum height of the terrain will be 20 units. The output has been edited and arranged neatly in columns, so that
you can see that the height of the eight outer vertices is 0 and the height of the central vertex is 10.
Last updated 8/26/2011
178