Adobe Director Basics

ADOBE DIRECTOR BASICS
3D: Controlling action
If the resulting vSpriteLoc is VOID, then the box is not allowed to move to the proposed new position.
Note: For more information on how the dragging feature is implemented, see “Dragging” on page 250.
spriteSpaceToWorldSpace()
The function spriteSpaceToWorldSpace works in reverse. For input, it accepts a 2D point, representing an offset from
the top left corner of the 3D sprite as a parameter. For output, it returns a 3D position vector representing one of the
points in the 3D world that appears under that point in the sprite.
At that location in the sprite, there will be an infinite number of 3D points. The precise value of the point is rarely useful
on its own. However, if you subtract the worldPosition of the camera from the value returned by
spriteSpaceToWorldSpace(), you obtain a vector pointing from the camera into the 3D world through that point.
Here is a handler called GetRayUnderLoc()that accepts two parameters:
aSpriteLoc : a 2D point, representing an offset from the top left corner of the 3D sprite
aCamera: the camera of the 3D sprite
The GetRayUnderLoc()handler returns a unit vector which points from the camera into the world. In other words,
GetRayUnderLoc() tells you the direction in which the mouse is pointing when it is at aSpriteLoc.
on GetRayUnderLoc(aSpriteLoc, aCamera)
vCameraLoc = aCamera.worldPosition
vDistantLoc = pCamera.spriteSpaceToWorldSpace(aSpriteLoc)
vRay = vDistantLoc - vCameraLoc
vRay.normalize()
return vRay
on GetRayUnderLoc
Placing a model under the mouse
Here's a mouseUp() handler from a 3D behavior. It will place a model named “Ball” so that its center appears directly
under the mouse at a distance of 200 world units from the camera:
on mouseUp(me)
vSprite = sprite(me.spriteNum)
vCamera = vSprite.camera
vCameraPoint = vCamera.worldPosition
vBall = vSprite.member.model("Ball")
vSpriteLoc = the mouseLoc - [vSprite.left, vSprite.top]
vWorldSpace = vCamera.spriteSpaceToWorldSpace(vSpriteLoc)
vRay = vWorldSpace - vCameraPoint
vRay.normalize()
vBallPoint = vCameraPoint + vRay * 200
vBall.worldPosition = vBallPoint
end mouseUp
To see a demonstration of this handler, download and launch the movie PlaceBall.dir.
Last updated 8/26/2011
249