Pratique de Sas Windows 9.2... Volume 1 - Ined

Et le classeur multifeuilles ?
La macro de la page suivante, rédigée à l’origine par Paul Choate * et adaptée, vous permettra de récupérer
sous formes de tables, TOUTES les feuilles d’un classeur, même si les noms de feuilles sont en double ou avec
des blancs ou commençant avec un nombre.
%macro xlcopy(path=,file=,Header=Yes,Mixed=No);
/* libname accès à Excel avec piochage en première ligne et
maintien du type num ou char*/
libname excelbk excel "&path.&file." Header=&Header Mixed=&Mixed ;
/* noms des feuilles */
proc sql noprint;
select memname into :xl1 - :xl999
from sashelp.vtable
where upcase(libname) = upcase('excelbk') ;
%let numds = &sqlobs;
quit;
/* transformées en noms autorisés de tables*/
%MACRO dsnames;
data file;
length file $32;
%DO I=1 %TO &numds;
file=compress("&&xl&i",' ','NK');
if anyfirst(file)>1 then substr(file,1,1)='_';
dsvar="ds&i";
output;
%END;
run;
%MEND dsnames;
%dsnames
proc sort data=file;
by file dsvar;
run;
/* si noms en doublons, renommer */
data _null_;
set file;
by file dsvar;
if first.file then n=0;
if not first.file then do;
n+1;
file=trim(file)||'_'||put(n,z2.);
end;
call symput(dsvar,trim(file));
run;
proc delete data=file;run;
/* Copies des feuilles */
%MACRO copyfl;
%DO I=1 %TO &numds;
proc sql noprint;
create table "&&ds&i"n as select *
from excelbk."&&xl&i"n;
quit;
%END;
%MEND copyfl;
%copyfl
libname excelbk clear;
%mend xlcopy;
%xlcopy(path=d:\sasv913\,file=libexcel.xls,Header=Yes,Mixed=No);
*Auteur également de ce texte pour la 9.1.3 ( !) avec Carol Martell
http://www2.sas.com/proceedings/sugi31/024-31.pdf
« DeMystifying the SAS® LIBNAME Engine in Microsoft Excel: A Practical Guide »
Je rajoute ici, à posteriori, un papier tout récent sur le libname:
« The Little Engine That Could: Using EXCEL LIBNAME Engine Options to Enhance Data Transfers
between SAS® and Microsoft® Excel Files » de William E Benjamin Jr
http://www.lexjansen.com/pharmasug/2010/ad/ad10.pdf
INED Wielki 107