Pratique de Sas Windows 9.2... Volume 1 - Ined

9.4.3 Des liens/links internes (ods pdf text= anchor= ) et les sauts de page (ods startpage= )
ods listing close;
ods escapechar="^";
options nodate nonumber;
ods pdf file="d:\tabsas\odspdfmonlien.pdf" notoc ;
title "Deux Rapports Différents";
ods pdf text="^S={just=c URL='#premier'} Toujours la fameuse classe";
ods pdf text="^S={just=c URL='#second'} Va où le coeur te porte";
ods pdf startpage=now;
title "La Classe!";
ods pdf anchor="premier";
proc report data=sashelp.class nowindows box;
columns AGE WEIGHT ;
define AGE/group width=20 ;
define WEIGHT/sum noprint;
compute after AGE;
line 'Total Weight: ' WEIGHT sum 3.;
endcomp;
run;
title "A coeur ouvert";
ods pdf anchor="second";
proc means data=sashelp.heart mean;
class sex; var systolic diastolic ;
run;
ods pdf close;
ods listing;
Commentaires:
Si la table des matières ne vous plait pas, créez la vôtre en mettant notoc tout en actionnant votre propre
construction à l’aide d’instructions ods text= renvoyant à des liens internes #qqch disséminés dans la production
ultérieure sous forme d’ancres par ods pdf anchor= .
Il a été nécessaire de faire appel à une instruction commandant le saut de page ods pdf startpage=now;
car en situation par défaut, le saut naturel de page ne fonctionne qu’au changement de procédure ou de valeur du
by.
Page 1 2 3
Ajoutant startpage=no sur l’instruction initial ods pdf après notoc, Sas retient l’ordre et ne sautera de page
que sur un ordre explicite now : ce qui fait qu’alors les deux résultats sont sur une seule seconde et dernière
page. Rappelons ici que par défaut la situation est startpage=yes.
INED Wielki 152