Pratique de Sas Windows 9.2... Volume 1 - Ined

9.6 La destination output (ou comment capturer e.a. des résultats statistiques)
Cette partie vous suppose familier de l’ods trace vu page 118.
Dans cet exemple illustratif portant sur des données réelles non présentes dans le sashelp, l’ods trace nous
fournit tout d’abord le nom exact sous SAS 9.2.3 version francisée des data objets d’une procédure catmod dans
laquelle il y a une longue série exploratoire de modèles semblables mais à petite variation.
Sortie ajoutée :
-------------
Nom : ANOVA Nom : Estimates
Libellé : Analyse de variance Libellé : Valeurs estimées ML
Modèle : Stat.Catmod.ANOVA Modèle : Stat.Catmod.Estimates
Chemin : Catmod.Model1.ANOVA Chemin : Catmod.Model1.Estimates
-------------
Programme :
ods results=off;
ods select ANOVA Estimates;
ods output "Analyse de Variance"(persist=proc)=anova;
ods output Estimates(persist=proc)=estimates(drop=note);
proc catmod data = EID.a_indpol ;
direct agee age2 ;
model polit = agee age2 sexee fnaactb / noprofile ;run;*1;
direct agee age2 ;
model polit = agee age2 sexee fnaactb nive2te / noprofile ;run;*2;
direct agee age2 ;
model polit = agee age2 sexee fnaactb nive2te qualife / noprofile ;run;*3;
direct agee age2 ;
model polit = agee age2 sexee fnaactb nive2te mressthh / noprofile ;run;*4;
quit;
ods output close;
ods results=on;
ods select all;
ods listing close;
ods html file="d:\ined\r\catmod.xls" style=minimal;
title 'anova';proc print data=anova;run;
title 'estimates';proc print data=estimates;run;
ods html close;ods listing;
Commentaires :
- Les noms d’objets sont ANOVA et Estimates et sont sélectionnés pour ensuite les capturer facilement.
- L’instructuction ods output exige que soit affecté à un nom d’objet (ou label, template ou path), un nom
de table sas temporaire. Dans l’exemple, c’est le libellé de l’objet ANOVA (qui se retrouvera sous ce nom
identique dans les 4 tentatives de modèlisation statistique) qui sera capturé pour remplir une table anova jusqu’à
la fin de la procédure, grâce à l’option persist=proc. Le label a dû être mis entre quotes vu un nom non simple.
Il en sera de même pour la récupération dans une autre table estimates (sur laquelle il est possible d’appliquer
des options de dataset drop= par ex) de l’autre ensemble d’informations.
- On prendra bien soin de fermer la table accumulant les informations par la passation d’une instruction ods
output close; seulement après avoir fermé les actions en cours par un run ; ou un quit ; préalable.
La seconde étape consite simplement à diriger l’affichage de leur contenu vers du html présenté partiellement
ci après, prouvant ainsi leur existence.
On pourra donc affirmer que tout résultat( statistique, tabulate…) est récupérable sous forme de table Sas et donc
utilisable directement pour une reprise et transformation. Certains résultats jamais imprimés/visibles le sont aussi : la
liste de ces objets se trouve à la fin de chaque chapitre de documentation sur une procédure statistique.
Sorties :
Anova
...
INED Wielki 161