Pratique de Sas Windows 9.2... Volume 1 - Ined

Avec ce mode d’emploi
http://support.sas.com/documentation/cdl/en/proc/61895/HTML/default/a003265389.htm
Autre exemple :
%macro maxage;
%local maxag;
proc sql noprint;
select max(AGE) into :MAXAG
from sashelp.class where SEX=&gender;
quit;
%let maxi=&maxag;
%mend maxage;
proc fcmp outlib=work.func.retest;
function maxAgeFor(gender $);
maxi = .;
rc = run_macro('maxage', gender, maxi);
if rc = 0 then return(maxi);
return(.);
endsub;
run;
%let cmplib=%sysfunc(getoption(cmplib));
options cmplib = (&cmplib work.func);
data _null_;
ans = maxAgeFor("F");
put "âge de la plus âgée: " ans;
run;
options cmplib = (&cmplib);
MPRINT(MAXAGE): proc sql noprint;
MPRINT(MAXAGE): select max(AGE) into :MAXAG
from sashelp.class where SEX='F';
MPRINT(MAXAGE): quit;
âge de la plus âgée: 15
On discutera certainement de la pertinence de cet exemple
par rapport à d’autres manières de faire, mais il illustre
l’usage d’une fonction macro !!!!
Et son fonctionnement est différent du call
execute !
Une procédure a été appelée dans l’étape data !
Logique :
-&gender comporte en fait déjà des doubles
quotes, car comme paramètre argument
caractère dans fcmp, il les possède déjà.
-Cependant enlever les quotes à l’appel,
fait considérer F comme variable.
-En testant le code retour du run_macro, on
renverra sous l’argument gender, en fait,
le contenu de la variable/fonction maxi
ayant été remplie par l’exécution de la
macro et gardée grâce au %let !
voir
http://support.sas.com/documentation/cdl/en/proc/61895/HTML/default/a003258539.htm
INED Wielki 196