SAS/STAT 9.2 User's Guide: The MIXED Procedure (Book Excerpt)

proc mixed;
class A B Block;
model Y = A B A*B;
random Block A*Block;
run;
An equivalent way of specifying this model is as follows:
proc mixed data=sp;
class A B Block;
model Y = A B A*B;
random intercept A / subject=Block;
run;
Example 56.2: Repeated Measures ✦ 4013
In general, if all of the effects in the RANDOM statement can be nested within one effect, you
can specify that one effect by using the SUBJECT= option. The subject effect is, in a sense, “factored
out” of the random effects. The specification that uses the SUBJECT= effect can result in
faster execution times for large problems because PROC MIXED is able to perform the likelihood
calculations separately for each subject.
Example 56.2: Repeated Measures
The following data are from Pothoff and Roy (1964) and consist of growth measurements for 11
girls and 16 boys at ages 8, 10, 12, and 14. Some of the observations are suspect (for example, the
third observation for person 20); however, all of the data are used here for comparison purposes.
The analysis strategy employs a linear growth curve model for the boys and girls as well as a
variance-covariance model that incorporates correlations for all of the observations arising from
the same person. The data are assumed to be Gaussian, and their likelihood is maximized to estimate
the model parameters. See Jennrich and Schluchter (1986), Louis (1988), Crowder and Hand
(1990), Diggle, Liang, and Zeger (1994), and Everitt (1995) for overviews of this approach to repeated
measures. Jennrich and Schluchter present results for the Pothoff and Roy data from various
covariance structures. The PROC MIXED statements to fit an unstructured variance matrix (their
Model 2) are as follows:
data pr;
input Person Gender $ y1 y2 y3 y4;
y=y1; Age=8; output;
y=y2; Age=10; output;
y=y3; Age=12; output;
y=y4; Age=14; output;
drop y1-y4;
datalines;
1 F 21.0 20.0 21.5 23.0
2 F 21.0 21.5 24.0 25.5
3 F 20.5 24.0 24.5 26.0
4 F 23.5 24.5 25.0 26.5
5 F 21.5 23.0 22.5 23.5