Pratique de Sas Windows ...9.3 Volume 2 - Ined

proc template;
define style Ks; parent=styles.default;
style header / foreground=red ;
style fonts / "docFont" = ("Times Roman, serif", 3) ;
end;run;
ods html close;ods preferences;
ods html file="d:\notes\test\HS2.htm" style=KS;
ods select members;
proc datasets ;
contents lib=work;
run;quit;
ods html close;
Dans cet exemple, ayant enlevé le from des instructions style, je n’ai pas eu d’héritage à partir du parent pour les
éléments de style retenus pour une définition d’attribut. J’ai créé un nouveau lignage échappant au système de
lignage défini dans base.template.style et il s’avère appauvri car il ne reste qu’une couleur pour cette classe
d’éléments et une police pour la classe font: fond blanc pour header et plus qu’une seule police définie.
Dans la classe Container (ancêtre) de styles.default, la définition docFont est utilisée ; il en découle donc aussi
le changement dans l’élément systemtitle.
Revenons à la syntaxe générale pour décrire la particularité de l’instruction Class
Dans le Styles.defaut, nous avons deux classes header et rowheader qui dépendent de l’élément
HeadersandFooters. Dans la définition d’un nouveau style, il sera autorisé, pour appliquer un changement
commun, de passer du code suivant tout en faisant jouer l’héritage
class header , rowheader from _self /
Font = ("Arial, Helvetica,sans-serif", 3,Bold)
foreground=red
background=white
just=center;
Par extension, le mot Class a été créé en 9.2 comme raccourci de style nomdelementdestyle from _self_ .
Cette instruction suivra le processus d’héritage fixé dans base.template.style et suivra les lignages résumés par
Perry Watts.
proc template;
define style Ks1; parent=styles.default;
style header / foreground=red;
style fonts from _self_/
"docFont" = ("Times Roman, serif", 3)
;
end;run;
Systemtitle reprend de la vigueur !
proc template;
define style Ks1; parent=styles.default;
class header / foreground=red ;
style fonts from _self_/
"docFont" = ("Times Roman, serif", 3)
;
end;run;
Header se rétablit !
Le processus d’héritage en sera plus complexe et essayez d’éviter un conflit familial en donnant priorité aux
enfants dans votre famille recomposée : définissez vos attributs au niveau éléments de style enfant, car ils ont
priorité. Les style from semblent apparement clairs, mais établissent aussi de nouveaux lignages. De plus, les
même noms d’attributs peuvent apparaître de multiples fois et dans de multiples éléments.
39 INED Service Informatique Wielki