Introduction to Stata 8 - (GRIPS

twoway connected; twoway rcap
100
80
Mean score
60
40
20
PF RP BP GH VT SF RE MH
SF-36 subscale
Observed
Expected
95% CI
// c:\dokumenter\...\gph.SF36a.do
clear
input scale n obs sd norm
1 139 60.81 27.35 70.77
2 139 37.65 42.06 62.01
...
8 139 73.06 21.54 79.99
end
generate se=sd/sqrt(n)
generate ci1=obs+1.96*se
generate ci2=obs-1.96*se
label define scale 1 "PF" 2 "RP" 3 "BP" 4 "GH" 5 "VT" 6 "SF" 7 "RE" 8 "MH"
label values scale scale
set scheme lean1
twoway ///
(connected obs scale , msymbol(O) clpattern(l)) ///
(connected norm scale , msymbol(O) mfcolor(white) clpattern(-)) ///
(rcap ci1 ci2 scale) ///
, ///
ytitle("Mean score") ///
xtitle("SF-36 subscale") ///
xlabel(1(1)8 , valuelabel noticks) ///
xscale(range(0.5 8.5)) ///
legend(label(1 "Observed") label(2 "Expected") label(3 "95% CI")) ///
xsize(4) ysize(2.3) scale(1.4)
This graph includes three plots; two connected and one rcap. In twoway plots both axes
are continuous, so you could not have a categorical variable (PF, RP etc.) at the x-axis.
Solution: use a numerical variable and use value labels to indicate the meaning. This graph
style is frequently used to present SF-36 results, although connecting lines may be illogical
when displaying eight qualitatively different scales.
xscale(range(0.5 8.5)) increased the distance between plot symbols and plot margin.
rcap does not calculate confidence intervals for you; it is up to you to provide two y- and
one x-value for each confidence interval. rspike would have plotted intervals without caps.
47