Über den Autor Holger Galuschke - FinanzBuch Verlag - Management

Code
Teil III Bessere Handelsergebnisse mit Trendfiltern von Björn Borchers –271
Inputs:
Value1( 0 ), // Prüfungswert bei der Rate of Change
Value2( 50 ), // Wert des DSS Bressert
Price( Close ), // Der Durchschnitt wird auf den Schlusskurs berechnet
Period( 52 ), // Der Parameter für den Durchschnitt (52 Wochen)
ChangePeriod( 10 ), // Der Parameter für die Rate of Change
BressertPrice( Close ), // Der DSS Bressert wird auf den Schlusskurs berechnet
BressertPeriod( 12 ), // Der Parameter von den DSS Bressert (12 Wochen)
Smooth( 3 ); // Die Glättung des DSS Bressert
// Die Indikatoren werden zur Vereinfachung als Variablen deklariert
Variables:
XAVG,
RATECHANGE,
DSSB;
XAVG = XAverage( Price, Period );
RATECHANGE = RateofChange( XAVG, ChangePeriod );
DSSB = DSSBressert( BressertPrice, BressertPeriod, Smooth );
// Kauf der Basisposition bei einem Aufwärtstrend
If RATECHANGE > Value1 Then
Buy ( "LONG-MA" ) 1 Share Next Bar At Market;
// Verkauf einer Basisposition bei einem Abwärtstrend
If RATECHANGE < Value1 Then
Short ( "SHORT-MA" ) 1 Share Next Bar At Market;
// Bedingung für den Kauf des Subsystems in einem Aufwärtstrend
If DSSB Crosses Over Value2 AND RATECHANGE > Value1 Then begin
Buy ( "LONG-DSSB" ) 1 Share Next Bar At Market;
// Profit Target in einem Aufwärtstrend
If Close > (PositionEntryPrice + 4.5*AvgTrueRange(12)) then
Sell ( "PT-LONG" ) From Entry( "LONG-DSSB" ) Next Bar At Market;
// Stop Loss in einem Aufwärtstrend
If Close < (PositionEntryPrice - 1.5*AvgTrueRange(12)) then
Sell ( "SL-LONG" ) From Entry( "LONG-DSSB" ) Next Bar At Market;
// Bedingung für den Verkauf des Subsystems in einem Aufwärtstrend
If DSSB Crosses Under Value2 Then
Sell ( "SELL-DSSB" ) From Entry( "LONG-DSSB" ) Next Bar At Market;
End;
// Bedingung für den Verkauf des Subsystems in einem Abwärtstrend
If DSSB Crosses Under Value2 AND RATECHANGE < Value1 Then begin
Short ( "SHORT-DSSB" ) 1 Share Next Bar At Market;
// Profit Target in einem Abwärtstrend
If Close < (PositionEntryPrice - 4.5*AvgTrueRange(12)) then
Cover ( "PT-SHORT" ) From Entry( "SHORT-DSSB" ) Next Bar At Market;
// Stop Loss in einem Abwärtstrend
If Close > (PositionEntryPrice + 1.5*AvgTrueRange(12)) then
Cover ( "SL-DSSB" ) From Entry( "SHORT-DSSB" ) Next Bar At Market;
// Bedingung für den Rückkauf des Subsystems in einem Abwärtstrend
If DSSB Crosses Over Value2 Then
Cover ( "COVER-DSSB" ) From Entry( "SHORT-DSSB" ) Next Bar At Market;
End;