Smalltalk and Object Orientation: an Introduction - Free

21.5.2 Adding an instance creation method
Now we have a class called BoxDrawFigure, we need some way of instantiating this class. HotDraw
expects a figure’s instance creation method to be called createAt: (rather than new or open with
which you may be more familiar). We will therefore define a method createAt: in the protocol
“instance creation”:
createAt: aPoint
^self new initializeAt: aPoint
This method first creates a new instance of the BoxDrawFigure and then sends it an
initializeAt: message with aPoint as the current cursor position . The initializeAt:
method will actually draw the figure and its component elements. We will look at this method below.
21.5.3 Defining a creation tool
While we are still on the class side, we shall define the creationTool method which specifies what
icon to use in the ToolPalette for a BoxDrawFigure. Rather than define a new
creationTool class, we will provide a creationTool method which will return the default
creationTool, parameterized for BoxDrawFigure. This method will be defined in the class protocol
“tool creation”. The creationTool method is:
creationTool
^Tool
icon: (Image
extent: 16 @ 16
depth: 1
palette: MappedPalette blackWhite
bits: #[255 255 255 255 255 255 128 1
191 253 160 125 191 253 160 197
191 253 160 125 191 253 28 1
255 255 255 255 255 255 255 255]
pad: 8)
cursor: Cursor crossHair
class: self
creationMessage: #createAt:
This method is based on that defined in PERTEvent in one of the HotDraw example applications. It
returns an instance of CreationTool which uses a particular icon on class BoxDrawFigure and
uses a crossHair (rather than origin) style cursor. Note that the creationMessage is specified here.
We could have used a different creation message to that used elsewhere in HotDraw. However, to
remain consistent with existing HotDraw applications we used createAt:.
21.5.4 The initializeAt: method
We now need to define what the elements of this drawing will be. That is, “what the figure will look
like”. This is done within initializeAt: defined in “initialize” protocol on the instance side of the
class. The code for this method is:
initializeAt: aPoint
| title myFigures aRectangle |
"Get the bounding rectangle"
aRectangle := aPoint extent: 90 @ 45.
origin := aRectangle origin.
"Position the text field relative to the origin"
title := FixedTextFigure string: 'A Name' at: origin + (5 @ 5).
title maxLength: 65.
"Add the text field to the subelements of this figure"
myFigures := (OrderedCollection new) add: title; yourself.
self setFigures: myFigures visibleArea: aRectangle.
"Draw the bounding box of this figure"
self showVisibleAreaIndicator.
This method first creates a rectangle whose right hand corner is indicates by aPoint and whose extent
is 90 by 45. Having done that, it then sets the origin of the figure relative to the rectangle. Next it
creates a text field at a particular point and then uses the bounding box of the figure to draw the shape of
the figure (in this case a rectangle).
178