Smalltalk and Object Orientation: an Introduction - Free

we access the value holder using value, it knows to return the string held by the text object within the
value holder. But when we update the value holder we need to wrap the string in a text object.
28.3.6 The “accessing” protocol
Next we shall define the methods in the “accessing” protocol. There are four methods in this protocol.
We shall first consider those associated with setting and updating the address book dictionary. The first
of these is used to initialize the instance variable addressBook and the second to add new name and
address associations to the addressBook. These are addressBook: and newAddress:for:
respectively. The addressBook: method is very straight forward and is presented below.
addressBook: aDictionary
"This is a n update method for the addressBook instance variable. It is used to
accept a new dictionary object to use for the addressBook. It is intended only for
use with the initialization method of the AddressBook class."
addressBook := aDictionary
The newAddress:for: method takes two parameters, the new address and the name. The method
uses two different Dictionary methods. The first is used to check to see if there is already an
addressBook entry with that name. We could not use the basic at: message as that generates an
error if the key provided with the at: message is not present in the dictionary. However, the
at:ifAbsent: message allows the code block provided with the ifAbsent: parameter to be run if
the key is not present. In our case we do not want it to do anything other than return nil. By default
when a block is evaluated it returns nil if nothing else is returned. We therefore only need to provide
any empty block which will always return the value nil. We can then test the value of the temporary
variable alreadyThere to see if it is nil. If it is nil then we can add the new name and address to
the dictionary held in addressBook. If it is not nil we can warn the user that an entry with that key
already exists using a dialog window.
newAddress: anAddress for: aName
"This method is used to add a new address to the address book."
| alreadyThere |
alreadyThere := addressBook at: aName ifAbsent: [].
alreadyThere isNil
ifTrue: [addressBook at: aName put: anAddress]
ifFalse: [Dialog warn: 'That key is already present']
We shall now consider the last two methods in this protocol. These methods are addressBook which
returns the contents of the addressBook instance variable and addressFor: which returns the
address associated with a particular name (if one is present). The addressBook method is:
addressBook
"This is an access method for the addressBook instance variable"
^addressBook
The addressFor: method is slightly more complex as it must handle the situation where an
address is not available (it uses the at:ifAbsent: message to do this).
addressFor: aName
"This method is used to retrieve an address from the address book."
| anEntry |
anEntry := addressBook at: aName ifAbsent: [nil].
^anEntry
28.3.7 A working application
If you have followed all the steps above correctly you should now have a working application. To start
the application, type the following into a Workspace and evaluate it:
VisualOrganizer open
This will display the window illustrated in Figure 28.2. Now select the Addresses option and you should
see a window such as that displayed in Figure 28.3. You can now type in a few names and addresses
selecting input between each. Next try out the query option by typing in a name and selecting query. If
242