Smalltalk and Object Orientation: an Introduction - Free

style := aSymbol
Next we define an updating protocol. This protocol will hold a single method addWidgetAt: .
This method adds the appropriate type of graphic object to the objects held in nodes. The instance
variable style is used to determine the type of object to add. The parameter aPoint indicates the
location, within the drawing view, at which the object should be displayed. Finally, the method informs
the drawingModel that something has changed and that its dependents may be interested in that
change.
addWidgetAt: aPoint
| aNode pos |
self style = #point ifTrue: [aNode := PointWidget new].
self style = #box ifTrue: [aNode := BoxWidget new].
self style = #circle ifTrue: [aNode := CircleWidget new].
aPoint = nil ifTrue: [pos := 0 @ 0] ifFalse: [pos := aPoint].
self nodes add: (aNode origin: pos).
self changed: #object with: aNode.
We will also define a single class side method new. This method will extend the functionality of the
new method by sending the message initialize to a newly created instance. The method is defined
in the class side protocol instance creation:
new
^super new initialize.
29.5.3 The DrawingView class
The DrawingView class is a subclass of the View class. It possesses a single instance variable called
defaultControllerClass. The contents of this variable will be used to instantiate the correct
type of controller (in this case an instance of DrawingController).
View subclass: #DrawingView
instanceVariableNames: 'defaultControllerClass '
classVariableNames: ''
poolDictionaries: ''
category: 'SmallDraw'
The class comment for the DrawingView class is left as an exercise for the reader.
The initialize method for the DrawingView class is defined as :
initialize
super initialize.
defaultControllerClass := DrawingController.
This method is defined within the initialize protocol. To ensure that all initialization done in
superclasses is also carried out in this class, the method first sends the message super initialize.
It then initializes the defaultControllerClass instance variable.
Following the conventions laid down in the system view class hierarchy we will define a
defaultControllerClass accessor method in a protocol referred to as controller accessing. This
method returns the contents of the defaultControllerClass instance variable:
defaultControllerClass
^defaultControllerClass
In the model accessing protocol we will define an updater method for the model associated with the
drawingView instance called model:
model: aModel
super model: aModel.
self invalidate.
This method uses an inherited version of the model: method to set the model and then sends the
message invalidate to itself. This informs the view that some part of what is currently being
displayed may need to be redrawn. This will cause a displayOn: aGraphicsContext message
to be sent to self.
252