Actionscript 3 Entwicklerhandbuch

ACTIONSCRIPT 3.0 ENTWICKLERHANDBUCH
Verwenden von Arrays
var names:Array = new Array("John Q. Smith", "Jane Doe", "Mike Jones");
function orderLastName(a, b):int
{
var lastName:RegExp = /\b\S+$/;
var name1 = a.match(lastName);
var name2 = b.match(lastName);
if (name1 < name2)
{
return -1;
}
else if (name1 > name2)
{
return 1;
}
else
{
return 0;
}
}
trace(names); // output: John Q. Smith,Jane Doe,Mike Jones
names.sort(orderLastName);
trace(names); // output: Jane Doe,Mike Jones,John Q. Smith
Bei der benutzerdefinierten Sortierfunktion orderLastName() wird mithilfe eines regulären Ausdrucks der
Nachname jedes Elements extrahiert und für den Vergleichsvorgang verwendet. Der Funktionsbezeichner
orderLastName wird als einziger Parameter beim Aufrufen der sort()-Methode für das names-Array verwendet. Für
die Sortierfunktion werden zwei Parameter (a und b) angegeben, da die Funktion auf zwei Array-Elemente gleichzeitig
angewendet wird. Der Rückgabewert der Sortierfunktion gibt die Sortierreihenfolge der Elemente an.
Der Rückgabewert -1 gibt an, dass der erste Parameter a vor dem zweiten Parameter b steht.
Der Rückgabewert 1 gibt an, dass der zweite Parameter b vor dem ersten Parameter a steht.
Der Rückgabewert 0 gibt an, dass die Sortierrangfolge der Elemente gleichwertig ist.
Die sortOn()-Methode (nur Array-Klasse)
Die sortOn()-Methode wird bei Array-Objekten mit Elementen eingesetzt, die Objekte enthalten. Diese Objekte
müssen über mindestens eine gemeinsame Eigenschaft verfügen, die als Sortierschlüssel verwendet werden kann. Die
Verwendung der sortOn()-Methode bei Arrays mit anderen Datentypen führt zu unerwarteten Ergebnissen.
Hinweis: Die Vector-Klasse enthält keine sortOn()-Methode. Diese Methode ist nur für Array-Objekte verfügbar.
Im folgenden Beispiel wird das poets-Array so geändert, dass jedes Element ein Objekt und kein String ist. Jedes
Objekt enthält den Nachnamen und das Geburtsjahr eines Dichters.
var poets:Array = new Array();
poets.push({name:"Angelou", born:"1928"});
poets.push({name:"Blake", born:"1757"});
poets.push({name:"cummings", born:"1894"});
poets.push({name:"Dante", born:"1265"});
poets.push({name:"Wang", born:"701"});
Letzte Aktualisierung 27.6.2012
36