Mac OS X Leopard - ARCAism

CHAPTER 23 MAC OS X AUTOMATION WITH AUTOMATOR AND APPLESCRIPT 415
tell application "Finder" to delete every file in (path to pictures folder)'s ➥
folder "Keyword Screensaver"
It’s a bit awkward but still understandable. Note the use of parentheses to clear up syntactical
ambiguities and the lack of end tell for the single-line version.
As expected, this displays the dialog:
display dialog "What keyword shall I search for?" default answer ""
The empty default answer clause gives you an empty text area for the user’s input. Without
it, the dialog would have just been informational. Note that the dialog is part of AppleScript
itself, so it doesn’t appear in any tell block.
This strange sentence is based on the fact that result is a secret keyword for the return value
of the dialog called earlier:
set _keyword to text returned of result
Concatenation is accomplished with the & operator:
set _queryURL to "http://images.google.com/images?q=" & _keyword
We’re not necessarily sure what type _keyword is, but it doesn’t matter. Although AppleScript
has variable types, a fact that occasionally rears its ugly head, most of the time type coercion
happens automatically.
As before, this block could have been rendered as a single line:
set _queryURL to "http://images.google.com/images?q=" & text returned ➥
of (display dialog "What keyword shall I search for?" default answer "")
Automator has several convenient Internet methods that AppleScript lacks. Instead of fetching
the results in the background and returning a list of links, you have to, somewhat tediously,
open Safari and load the results page:
tell application "Safari"
open location _queryURL
There’s no way to know when the page is done loading, so you have to poll it. Since it might
not actually load, you have to set a timeout:
set _timeoutInSeconds to 20
Since it will take at least a couple of seconds, you wait for 2 right off the bat:
delay 2
As mentioned, AppleScript has several looping constructs. This one iterates from one number
to another:
repeat with _waitInSeconds from 1 to _timeoutInSeconds
AppleScript also has branching, via the if then...else if then...else construct. Although
the then keyword is required, the Script Editor will fill it in for you if you forget it:
if (do JavaScript "document.readyState" in document 1) is "complete" then
Not unlike Automator, AppleScript can call other languages, though technically it’s Safari,
not AppleScript, that provides the do JavaScript functionality.
This is equivalent to the break statement in C. It is similar to, but not interchangeable with,
end repeat, which ends the loop syntax.
exit repeat