Processing: Creative Coding and Computational Art

velocity.vx *= damping;
}
}
There’s nothing new here. You’ve dealt with these types of orthogonal collisions a number
of times before. The steps to handle the wall collision, as a refresher, are as follows:
1. Keep the orb from moving too far through the wall by assigning the precise value
of the point of collision to the orb’s x property (orb.x = width-orb.r;).
2. Reverse the orb’s velocity (along the x-axis).
3. Optionally dampen the velocity along the x-axis upon collision.
Finally, the ground collision function is where you’ll rotate the coordinate space to temporarily
convert the challenging non-orthogonal collision problem to a much simpler
orthogonal one. Create a tab named checkGroundCollision and enter the following code:
void checkGroundCollision() {
// get difference between orb and ground
float deltaX = orb.x - ground.x;
float deltaY = orb.y - ground.y;
// precalculate trig values
float cosine = cos(ground.rot);
float sine = sin(ground.rot);
/* rotate ground and velocity to allow
orthogonal collision calculations */
float groundXTemp = cosine * deltaX + sine * deltaY;
float groundYTemp = cosine * deltaY - sine * deltaX;
float velocityXTemp = cosine * velocity.vx + sine * velocity.vy;
float velocityYTemp = cosine * velocity.vy - sine * velocity.vx;
// ground collision
if (groundYTemp > -orb.r){
// keep orb from going into ground
groundYTemp = -orb.r;
// bounce and slow down orb
velocityYTemp *= -1.0;
velocityYTemp *= damping;
}
// reset ground, velocity and orb
deltaX = cosine * groundXTemp - sine * groundYTemp;
deltaY = cosine * groundYTemp + sine * groundXTemp;
velocity.vx = cosine * velocityXTemp - sine * velocityYTemp;
velocity.vy = cosine * velocityYTemp + sine * velocityXTemp;
orb.x = ground.x + deltaX;
orb.y = ground.y + deltaY;
}
MOTION
537
11