The Kyma Language for Sound Design, Version 4.5

Recursion
First we create a TimedEventSequence from a MIDI file. § Then we get rid of any polyphony using the
asMonophonicEventSequence message. Then we create a MarkovChain (length 3), using the events
from the TimedEventCollection. We then ask the MarkovChain to create a new sequence. Finally, we
create a new EventSequence, supplying the Markov-generated sequence as the events. When the example
plays, you will hear one part of the original sequence, followed by the Markov-generated sequence.
Take a look at the Sound called self similar melody. This script is an example of how you can create a
Smalltalk “block” and then call it recursively:
| pitchShape durationShape shapingFunction selfSimMel |
pitchShape := #(0 7 -12).
durationShape := #({2/5} {1/5} {2/5}).
shapingFunction := [ :seq :count |
count = 0
ifTrue: [seq]
ifFalse: [
EventSequence events:
((1 to: pitchShape size) collect: [ :i |
shapingFunction
value:
((seq trsp: (pitchShape at: i))
dim: (durationShape at: i))
value: count - 1])]].
selfSimMel :=
shapingFunction
value: (Note frequency: 4 c durationInBeats: 16)
value: 4.
selfSimMel playOnVoice: self onBeat: 0 bpm: 45.
As usual, we start by declaring the variables. Then we set pitchShape to an Array of intervals specified
in half steps, and we set durationShape to an Array of ratios, each of which corresponds to an amount
by which to scale a duration:
| pitchShape durationShape shapingFunction selfSimMel |
pitchShape := #(0 7 -12).
durationShape := #({2/5} {1/5} {2/5}).
Next we store an entire block of code (i.e., everything within the square brackets) in a variable called
shapingFunction. This block has two arguments (:seq and :count), and they are listed at the very
beginning of the block, separated from the rest of the block by a vertical bar. The code within the block is
not executed at this point; it is just stored in a variable so it can be executed later:
shapingFunction := [ :seq :count |
count = 0
ifTrue: [seq]
ifFalse: [
EventSequence events:
((1 to: pitchShape size) collect: [ :i |
shapingFunction
value:
((seq trsp: (pitchShape at: i))
dim: (durationShape at: i))
value: count - 1])]].
§ Thanks to Bill Walker (walker@taurus.apple.com) for the MIDI file DESAFIN1.MID.
146