Guide de reference du langage ActionScript 2.0 - PowWeb

onLoadStart (écouteur d'événement
MovieClipLoader.onLoadStart)
onLoadStart = function([target_mc:MovieClip]) {}
Appelé lorsqu'un appel à MovieClipLoader.loadClip() a commencé à charger un fichier.
Appelle cet écouteur sur un objet d'écoute que vous ajoutez à l'aide de
MovieClipLoader.addListener().
La valeur target_mc identifie le clip pour lequel cet appel est effectué. Ce paramètre est
particulièrement utile si vous chargez plusieurs fichiers avec le même jeu d'écouteurs.
Disponibilité : ActionScript 1.0 ; Flash Player 7
Paramètres
target_mc:MovieClip [facultatif] - Clip chargé par la méthode
MovieClipLoader.loadClip().
Exemple
L'exemple suivant charge une image dans une occurrence de clip appelée image_mc. Les
événements onLoadInit et onLoadComplete permettent de déterminer le temps de
chargement de l'image. Les informations s'affichent dans le champ texte appelé timer_txt.
this.createEmptyMovieClip("image_mc", this.getNextHighestDepth());
var mclListener:Object = new Object();
mclListener.onLoadStart = function(target_mc:MovieClip) {
target_mc.startTimer = getTimer();
};
mclListener.onLoadComplete = function(target_mc:MovieClip) {
target_mc.completeTimer = getTimer();
};
mclListener.onLoadInit = function(target_mc:MovieClip) {
var timerMS:Number = target_mc.completeTimer-target_mc.startTimer;
target_mc.createTextField("timer_txt", target_mc.getNextHighestDepth(),
0, target_mc._height,
target_mc._width, 22);
target_mc.timer_txt.text = "loaded in "+timerMS+" ms.";
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.helpexamples.com/flash/images/image1.jpg",
image_mc);
Si votre fichier SWF comprend un composant de la version 2, utilisez les composants de la
version 2 de la classe DepthManager au lieu de la méthode
MovieClip.getNextHighestDepth(), utilisée dans cet exemple.
996 Chapitre 2: Classes ActionScript